arm-gcs: add recipe for GDB with GCS support

The GCS support patches are based on GDB 15.
Copy the GDB 14.2 recipe from meta, upgrade to 15.1, and add the patches.

Signed-off-by: James McGregor <james.mcgregor2@arm.com>

meta-arm-gcs/recipes-devtools/gdb/gdb_15.1.bb

@@ -0,0 +1,40 @@
+require recipes-devtools/gdb/gdb-common.inc
+
+inherit gettext pkgconfig
+
+PACKAGES =+ "gdbserver"
+FILES:gdbserver = "${bindir}/gdbserver"
+
+require recipes-devtools/gdb/gdb.inc
+
+FILESEXTRAPATHS:prepend := "${COREBASE}/meta/recipes-devtools/gdb/gdb:"
+
+# This patch doesn't apply to 15.1
+SRC_URI:remove = "file://0005-Change-order-of-CFLAGS.patch"
+SRC_URI[sha256sum] = "38254eacd4572134bca9c5a5aa4d4ca564cbbd30c369d881f733fb6b903354f2"
+
+inherit python3-dir
+
+EXTRA_OEMAKE:append:libc-musl = "\
+                                 gt_cv_func_gnugettext1_libc=yes \
+                                 gt_cv_func_gnugettext2_libc=yes \
+                                 gl_cv_func_working_strerror=yes \
+                                 gl_cv_func_strerror_0_works=yes \
+                                 gl_cv_func_gettimeofday_clobber=no \
+                                "
+
+do_configure:prepend() {
+	if [ "${@bb.utils.filter('PACKAGECONFIG', 'python', d)}" ]; then
+		cat > ${WORKDIR}/python << EOF
+#!/bin/sh
+case "\$2" in
+	--includes) echo "-I${STAGING_INCDIR}/${PYTHON_DIR}${PYTHON_ABI}/" ;;
+	--ldflags) echo "-Wl,-rpath-link,${STAGING_LIBDIR}/.. -Wl,-rpath,${libdir}/.. -lpthread -ldl -lutil -lm -lpython${PYTHON_BASEVERSION}${PYTHON_ABI}" ;;
+	--exec-prefix) echo "${exec_prefix}" ;;
+	*) exit 1 ;;
+esac
+exit 0
+EOF
+		chmod +x ${WORKDIR}/python
+	fi
+}

meta-arm-gcs/recipes-devtools/gdb/gdb_15.1.bbappend

@@ -0,0 +1,3 @@
+FILESEXTRAPATHS:prepend := "${THISDIR}/files:"
+
+SRC_URI += "file://gcs.patch"