Use Linaro kernel for Juno Yocto BSP

In order to have SCMi or HDMI support, the Juno BSP must use
the Linaro kernel instead of the standard Yocto one.

Change-Id: Ib53cb81a074439e9a4018bf356d749c7fd0a5d5a
Signed-off-by: Vineeth Raveendran <vineeth.raveendran@arm.com>

meta-arm-bsp/conf/machine/juno.conf

@@ -17,8 +17,9 @@ IMAGE_FSTYPES += "tar.bz2 ext4"
 
 SERIAL_CONSOLES = "115200;ttyAMA0"
 
-PREFERRED_PROVIDER_virtual/kernel = "linux-yocto"
+# Use kernel provided by linaro (Contains support for SCMi or HDMI)
-PREFERRED_VERSION_linux-yocto ?= "4.19%"
+PREFERRED_PROVIDER_virtual/kernel = "linux-linaro-arm"
+PREFERRED_VERSION_linux-linaro-arm ?= "4.19%"
 
 EXTRA_IMAGEDEPENDS += "virtual/trusted-firmware-a u-boot"
 

meta-arm-bsp/recipes-kernel/linux/arm-platforms-kmeta/bsp/arm-platforms/juno/juno-board.cfg

@@ -12,6 +12,12 @@ CONFIG_SERIO_AMBAKMI=y
 CONFIG_MAILBOX=y
 CONFIG_ARM_MHU=y
 
+# SCMI support
+CONFIG_ARM_SCMI_PROTOCOL=y
+CONFIG_ARM_SCMI_POWER_DOMAIN=y
+CONFIG_SENSORS_ARM_SCMI=y
+CONFIG_COMMON_CLK_SCMI=y
+
 # Power Interface and system control
 CONFIG_ARM_SCPI_PROTOCOL=y
 CONFIG_ARM_SCPI_POWER_DOMAIN=y

meta-arm-bsp/recipes-kernel/linux/linux-linaro-arm_4.19.bb

@@ -0,0 +1,31 @@
+# Recipe for building linaro provided kernel
+
+KBRANCH ?= "latest-4.19-armlt-19.01"
+
+require recipes-kernel/linux/linux-yocto.inc
+
+
+SRCREV_machine ?= "e97e8d868aba53467039dbef3b7436c857433ae3"
+
+SRCREV_meta ?= "ad6f8b357720ca8167a090713b7746230cf4b314"
+
+SRC_URI = "git://git.linaro.org/landing-teams/working/arm/kernel-release.git;name=machine;branch=${KBRANCH}; \
+           git://git.yoctoproject.org/yocto-kernel-cache;type=kmeta;name=meta;branch=yocto-4.19;destsuffix=${KMETA} \
+          "
+
+LIC_FILES_CHKSUM = "file://COPYING;md5=bbea815ee2795b2f4230826c0c6b8814"
+LINUX_VERSION ?= "4.19.0"
+
+DEPENDS += "${@bb.utils.contains('ARCH', 'x86', 'elfutils-native', '', d)}"
+DEPENDS += "openssl-native util-linux-native"
+
+PV = "${LINUX_VERSION}+git${SRCPV}"
+
+KMETA = "kernel-meta"
+KCONF_BSP_AUDIT_LEVEL = "2"
+
+# Functionality flags
+KERNEL_EXTRA_FEATURES ?= "features/netfilter/netfilter.scc"
+KERNEL_FEATURES_append = " ${KERNEL_EXTRA_FEATURES}"
+KERNEL_FEATURES_append = " ${@bb.utils.contains("TUNE_FEATURES", "mx32", " cfg/x32.scc", "" ,d)}"
+KERNEL_FEATURES_append = " ${@bb.utils.contains("DISTRO_FEATURES", "ptest", " features/scsi/scsi-debug.scc", "" ,d)}"

meta-arm-bsp/recipes-kernel/linux/linux-linaro-arm_4.19.bbappend

@@ -0,0 +1,3 @@
+# Add support for Arm Platforms (boards or simulators)
+
+require linux-yocto-arm-platforms.inc