python3-pandas: Upgrade to 2.2.3

Fixes build with cython >=3.1
Drop patch to pin numpy to 1.x
Edit out absolute paths from cython generated C files

Cc: Martin Jansa <martin.jansa@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

meta-python/recipes-devtools/python/python3-pandas_2.2.3.bb

@@ -0,0 +1,44 @@
+SUMMARY  = "pandas library for high-performance data analysis tools"
+DESCRIPTION = "pandas is an open source, BSD-licensed library providing \
+high-performance, easy-to-use data structures and data analysis tools for \
+the Python programming language."
+HOMEPAGE = "https://pandas.pydata.org/"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=cb819092901ddb13a7d0a4f5e05f098a"
+
+SRC_URI += " \
+            file://0001-pyproject.toml-don-t-pin-dependency-versions.patch \
+            "
+
+SRC_URI:append:class-target = " file://0001-BLD-add-option-to-specify-numpy-header-location.patch "
+
+SRC_URI[sha256sum] = "4f18ba62b61d7e192368b84517265a99b4d7ee8912f8708660fb4a366cc82667"
+
+inherit pkgconfig pypi python_mesonpy cython
+
+DEPENDS += " \
+    python3-numpy \
+    python3-versioneer-native \
+"
+
+CFLAGS:append:toolchain-clang = " -Wno-error=deprecated-declarations"
+
+RDEPENDS:${PN} += " \
+    python3-json \
+    python3-numpy \
+    python3-dateutil \
+    python3-dateutil-zoneinfo \
+    python3-pytz \
+    python3-profile \
+"
+
+PYTHONPATH:prepend:class-target = "${RECIPE_SYSROOT}${PYTHON_SITEPACKAGES_DIR}:"
+export PYTHONPATH
+
+do_compile:append() {
+    # Fix absolute paths in generated files
+    find ${B} -name "*.c" -o -name "*.cpp" | xargs -r \
+        sed -i 's|${WORKDIR}/pandas-${PV}/|${TARGET_DBGSRC_DIR}/|g'
+}
+
+EXTRA_OEMESON:append:class-target = " -Dnumpy_inc_dir=${RECIPE_SYSROOT}${PYTHON_SITEPACKAGES_DIR}/numpy/_core/include "