python3-setproctitle: upgrade 1.3.7 -> 1.3.8

Changelog:
https://github.com/dvarrazzo/py-setproctitle/releases/tag/version-1.3.8

PTEST pass:

root@qemux86-64:~# ptest-runner python3-setproctitle
START: ptest-runner
2026-10-16T03:19
BEGIN: /usr/lib/python3-setproctitle/ptest
...
...
Testsuite summary
# TOTAL: 27
# PASS: 24
# SKIP: 3
# XFAIL: 0
# FAIL: 0
# XPASS: 0
# ERROR: 0
DURATION: 40
END: /usr/lib/python3-setproctitle/ptest
2026-10-16T03:20
STOP: ptest-runner
TOTAL: 1 FAIL: 0

Signed-off-by: Ankur Tyagi <ankur.tyagi85@gmail.com>
Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>

meta-python/recipes-devtools/python/python3-setproctitle_1.3.8.bb

@@ -0,0 +1,35 @@
+SUMMARY = "A Python module to customize the process title"
+DESCRIPTION = "The setproctitle module allows a process to change its \
+title (as displayed by system tools such as ps, top or MacOS Activity \
+Monitor)."
+HOMEPAGE = "https://github.com/dvarrazzo/py-setproctitle"
+BUGTRACKER = "https://github.com/dvarrazzo/py-setproctitle/issues"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=a9efff04c3ae658687dd38e20398a20d"
+
+inherit pypi setuptools3 ptest
+
+SRC_URI[sha256sum] = "cafe209d064a6efb88cb45a03e97981ff8832802b2b5d009dde0197a3b7b41c8"
+
+SRC_URI += " \
+    file://run-ptest \
+"
+
+RDEPENDS:${PN}-ptest += "\
+    libatomic-dev \
+    packagegroup-core-buildessential \
+    procps-ps \
+    python3-dev \
+    python3-multiprocessing \
+    python3-pytest \
+    python3-unittest-automake-output \
+"
+
+do_install_ptest() {
+    install -d ${D}${PTEST_PATH}/tests
+    cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
+}
+
+BBCLASSEXTEND = "native nativesdk"
+
+INSANE_SKIP:${PN}-ptest = "dev-deps"