gnome-keyring: upgrade 3.28.2 -> 3.34.0

* add upstream-version-is-even to inherit
* they moved to gettext-only translation
* add PACKAGECONFIG ssh-agent enabled by default
* RDEPENDS do not seem to make sense these days
* prettify recipe

[1] https://download.gnome.org/core/3.32/3.32.2/sources/

Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

meta-gnome/recipes-gnome/gnome-keyring/gnome-keyring/0001-Set-paths-to-ssh-agent-and-ssh-add-by-configure-opti.patch

@@ -0,0 +1,42 @@
+From e6464e01bc1cdf5496be2942d1bac41aa609f47e Mon Sep 17 00:00:00 2001
+From: =?UTF-8?q?Andreas=20M=C3=BCller?= <schnitzeltony@gmail.com>
+Date: Thu, 23 May 2019 23:44:06 +0200
+Subject: [PATCH] Set paths to ssh-agent and ssh-add by configure options
+MIME-Version: 1.0
+Content-Type: text/plain; charset=UTF-8
+Content-Transfer-Encoding: 8bit
+
+We have no executables in our sysroot so configuration won't find them.
+
+Upstream-Status: Inappropriate [OE specific]
+
+Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
+---
+ configure.ac | 11 +++++++++--
+ 1 file changed, 9 insertions(+), 2 deletions(-)
+
+diff --git a/configure.ac b/configure.ac
+index 4b83664..eda0c96 100644
+--- a/configure.ac
++++ b/configure.ac
+@@ -351,8 +351,15 @@ if test "$enable_ssh_agent" = "no"; then
+ 	SSH_AGENT=false
+ 	SSH_ADD=false
+ else
+-	AC_PATH_PROG([SSH_AGENT], [ssh-agent], [no])
+-	AC_PATH_PROG([SSH_ADD], [ssh-add], [no])
++    AC_ARG_WITH([ssh-agent-path],
++                [AC_HELP_STRING([--with-ssh-agent-path=PATH],
++                                 [path to ssh-agent])],
++                 [SSH_AGENT=$with_ssh_agent_path], [SSH_AGENT=no])
++    AC_ARG_WITH([ssh-add-path],
++                [AC_HELP_STRING([--with-ssh-add-path=PATH],
++                                 [path to ssh-add])],
++                 [SSH_ADD=$with_ssh_add_path], [SSH_ADD=no])
++
+ 	if test "$SSH_AGENT" = "no" -o "$SSH_ADD" = "no"; then
+ 		AC_MSG_ERROR([the ssh-agent and ssh-add commands were not found])
+ 	else
+-- 
+2.20.1
+

meta-gnome/recipes-gnome/gnome-keyring/gnome-keyring_3.28.2.bb

@@ -1,44 +0,0 @@
-SUMMARY = "Password and keyring managing daemon"
-HOMEPAGE = "http://www.gnome.org/"
-BUGTRACKER = "https://bugzilla.gnome.org/"
-SECTION = "x11/gnome"
-
-LICENSE = "GPLv2+ & LGPLv2+ & LGPLv2.1+"
-LIC_FILES_CHKSUM = " \
-    file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
-    file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c \
-"
-
-inherit features_check gnomebase remove-libtool gettext upstream-version-is-even
-
-DEPENDS = " \
-    intltool-native \
-    glib-2.0-native \
-    gtk+3 \
-    gcr \
-    libgcrypt \
-    ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)} \
-"
-
-SRC_URI[archive.md5sum] = "284580f954f762caf62aed2ae7358177"
-SRC_URI[archive.sha256sum] = "81171b7d07211b216b4c9bb79bf2deb3deca18fe8d56d46dda1c4549b4a2646a"
-SRC_URI += "file://musl.patch"
-
-REQUIRED_DISTRO_FEATURES = "x11"
-
-RDEPENDS_${PN} = "libgnome-keyring glib-2.0-utils"
-
-EXTRA_OECONF = "--disable-doc \
-                ac_cv_path_SSH_AGENT=${bindir}/ssh-agent \
-                ac_cv_path_SSH_ADD=${bindir}/ssh-add"
-
-PACKAGECONFIG ?= "${@bb.utils.filter('DISTRO_FEATURES', 'pam', d)}"
-PACKAGECONFIG[pam] = "--enable-pam --with-pam-dir=${base_libdir}/security, --disable-pam"
-PACKAGECONFIG[ssh-agent] = "--enable-ssh-agent,--disable-ssh-agent,,openssh-misc"
-
-FILES_${PN} += " \
-    ${datadir}/dbus-1/services \
-    ${datadir}/p11-kit \
-    ${base_libdir}/security/*${SOLIBSDEV} \
-    ${libdir}/pkcs11/gnome-keyring-pkcs11.so \
-"

meta-gnome/recipes-gnome/gnome-keyring/gnome-keyring_3.34.0.bb

@@ -0,0 +1,51 @@
+SUMMARY = "Password and keyring managing daemon"
+HOMEPAGE = "http://www.gnome.org/"
+BUGTRACKER = "https://bugzilla.gnome.org/"
+SECTION = "x11/gnome"
+
+LICENSE = "GPLv2+ & LGPLv2+ & LGPLv2.1+"
+LIC_FILES_CHKSUM = " \
+    file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263 \
+    file://COPYING.LIB;md5=4fbd65380cdd255951079008b364516c \
+"
+
+DEPENDS = " \
+    glib-2.0-native \
+    gtk+3 \
+    gcr \
+    libgcrypt \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)} \
+"
+
+inherit gnomebase gsettings features_check remove-libtool gettext upstream-version-is-even
+
+REQUIRED_DISTRO_FEATURES = "x11"
+
+SRC_URI[archive.md5sum] = "7c8fd85e46ed4ba1add0288b2ead9aec"
+SRC_URI[archive.sha256sum] = "e9cda9542a3e37c61636145e7e9e2513c569092ea8020752a834e1f40ad41943"
+SRC_URI += " \
+    file://0001-Set-paths-to-ssh-agent-and-ssh-add-by-configure-opti.patch \
+    file://musl.patch \
+"
+
+PACKAGECONFIG ??= "ssh-agent"
+PACKAGECONFIG[ssh-agent] = "--enable-ssh-agent --with-ssh-agent-path=${bindir}/ssh-agent --with-ssh-add-path=${bindir}/ssh-add,--disable-ssh-agent,,openssh-misc"
+
+EXTRA_OECONF = " \
+    --disable-doc \
+    ${@bb.utils.contains('DISTRO_FEATURES', 'pam', '--enable-pam --with-pam-dir=${base_libdir}/security', '--disable-pam', d)} \
+"
+
+FILES_${PN} += " \
+    ${datadir}/dbus-1/services \
+    ${datadir}/p11-kit \
+    ${base_libdir}/security/*${SOLIBSDEV} \
+    ${libdir}/pkcs11/gnome-keyring-pkcs11.so \
+"
+
+# fix | gnome-keyring-daemon: insufficient process capabilities, unsecure memory might get used
+# This does not make it through pseudo so perform on-target - sigh
+pkg_postinst_ontarget_${PN} () {
+    setcap cap_ipc_lock+ep `which gnome-keyring-daemon`
+}
+RDEPENDS_${PN} += "libcap-bin"