apache2: add from OE-Classic, update to version 2.4.2 and fix

* Enable threading for PHP
* Backport a number of patches
* Use apachectl in init script
* Install modules into a sane location
* Ensure apxs script is installed into sysroot in crossscripts directory
  and modified so that it works for building PHP
* Install httpd executable for native version so that PHP configure
  script can call it
* Rename server-makefile-patch to server-makefile.patch and drop
  apply=yes
* Add LIC_FILES_CHKSUM
* Fix packaging QA warnings
* Add LSB headers to init script
* Clean out some cruft and move packaging stuff after do_install

Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com>

meta-webserver/recipes-httpd/apache2/apache2-native_2.4.2.bb

@@ -0,0 +1,43 @@
+DESCRIPTION = "The Apache HTTP Server is a powerful, efficient, and \
+extensible web server."
+SUMMARY = "Apache HTTP Server"
+HOMEPAGE = "http://httpd.apache.org/"
+DEPENDS = "expat-native pcre-native apr-native apr-util-native"
+SECTION = "net"
+LICENSE = "Apache-2.0"
+PR = "r0"
+
+inherit native
+
+SRC_URI = "http://www.apache.org/dist/httpd/httpd-${PV}.tar.bz2"
+
+S = "${WORKDIR}/httpd-${PV}"
+
+LIC_FILES_CHKSUM = "file://LICENSE;md5=eff226ae95d0516d6210ed77dfdf2dcc"
+SRC_URI[md5sum] = "6bb12f726e22656f0ad2baf91f1f8329"
+SRC_URI[sha256sum] = "5382f9c507d3d02706e33d6308ea041f39e8511b5948aef0ca188df8f90159b8"
+
+do_configure () {
+	./configure --with-apr=${STAGING_BINDIR_CROSS}/apr-1-config \
+		--with-apr-util=${STAGING_BINDIR_CROSS}/apu-1-config \
+		--prefix=${prefix} --datadir=${datadir}/apache2
+}
+
+do_install () {
+	install -d ${D}${bindir} ${D}${libdir}
+	cp server/gen_test_char ${D}${bindir}
+	install -m 755 support/apxs ${D}${bindir}/
+	install -m 755 httpd ${D}${bindir}/
+	install -d ${D}${datadir}/apache2/build
+	cp build/*.mk ${D}${datadir}/apache2/build
+	cp build/instdso.sh ${D}${datadir}/apache2/build
+
+	install -d ${D}${includedir}/apache2
+	cp include/* ${D}${includedir}/apache2
+	cp os/unix/os.h ${D}${includedir}/apache2
+	cp os/unix/unixd.h ${D}${includedir}/apache2
+
+	cp support/envvars-std ${D}${bindir}/envvars
+	chmod 755 ${D}${bindir}/envvars
+}
+