mirrors/meta-openembedded
1
0
Fork 0
mirror of https://github.com/openembedded/meta-openembedded.git synced 2026-07-17 04:37:19 +00:00
Code Issues Projects Releases Wiki Activity

netdata: Upgrade 1.36.1 -> 1.43.0

Browse Source 
libyaml dependency now required. See:
6ee42875c: Bundle libyaml

json-c also seems required now. If I don't enable it, I get compile errors.

compression and https options got renamed upstream to lz4 and openssl. See:
c74bf56ee: Code reorg and cleanup - enrichment of /api/v2

Signed-off-by: Sam Van Den Berge <sam.van.den.berge@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
(cherry picked from commit 2dda30d3a4)
Signed-off-by: Armin Kuster <akuster808@gmail.com>
This commit is contained in:
Sam Van Den Berge
2023-10-19 10:02:54 +02:00
committed by Armin Kuster
parent cc4bd29840
commit 2907e217d1
1 changed files with 6 additions and 6 deletions
Download Patch File Download Diff File Expand all files Collapse all files
meta-webserver/recipes-webadmin/netdata/netdata_1.43.0.bb
+82
View File
@@ -0,0 +1,82 @@
SUMMARY = "Real-time performance monitoring"
DESCRIPTION = "Netdata is high-fidelity infrastructure monitoring and troubleshooting. \
Open-source, free, preconfigured, opinionated, and always real-time."
HOMEPAGE = "https://github.com/netdata/netdata/"
LICENSE = "GPL-3.0-only"
LIC_FILES_CHKSUM = "file://LICENSE;md5=fc9b848046ef54b5eaee6071947abd24"
DEPENDS += "libuv util-linux zlib libyaml json-c"
SRC_URI = "https://github.com/${BPN}/${BPN}/releases/download/v${PV}/${BPN}-v${PV}.tar.gz \
"
SRC_URI[sha256sum] = "d3c66273d8eb62290d412c870dcde45ea214ad187df9d5350f682d9e6d19d426"
# default netdata.conf for netdata configuration
SRC_URI += "file://netdata.conf"
# file for providing systemd service support
SRC_URI += "file://netdata.service"
UPSTREAM_CHECK_URI = "https://github.com/netdata/netdata/releases"
S = "${WORKDIR}/${BPN}-v${PV}"
# Stop sending anonymous statistics to Google Analytics
NETDATA_ANONYMOUS ??= "enabled"
inherit pkgconfig autotools-brokensep useradd systemd
LIBS:toolchain-clang:x86 = "-latomic"
LIBS:riscv64 = "-latomic"
LIBS:riscv32 = "-latomic"
LIBS:mips = "-latomic"
export LIBS
#systemd
SYSTEMD_PACKAGES = "${PN}"
SYSTEMD_SERVICE:${PN} = "netdata.service"
SYSTEMD_AUTO_ENABLE:${PN} = "enable"
#User specific
USERADD_PACKAGES = "${PN}"
USERADD_PARAM:${PN} = "--system --no-create-home --home-dir ${localstatedir}/run/netdata --user-group netdata"
PACKAGECONFIG ??= "openssl"
PACKAGECONFIG[cloud] = "--enable-cloud, --disable-cloud,"
PACKAGECONFIG[lz4] = "--enable-lz4, --disable-lz4, lz4"
PACKAGECONFIG[openssl] = "--enable-openssl, --disable-openssl, openssl"
# ebpf doesn't compile (or detect) the cross compilation well
EXTRA_OECONF += "--disable-ebpf"
do_install:append() {
#set S UID for plugins
chmod 4755 ${D}${libexecdir}/netdata/plugins.d/apps.plugin
if ${@bb.utils.contains('DISTRO_FEATURES','systemd','true','false',d)}; then
# Install systemd unit files
install -d ${D}${systemd_unitdir}/system
install -m 0644 ${WORKDIR}/netdata.service ${D}${systemd_unitdir}/system
sed -i -e 's,@@datadir,${datadir_native},g' ${D}${systemd_unitdir}/system/netdata.service
fi
# Install default netdata.conf
install -d ${D}${sysconfdir}/netdata
install -m 0644 ${WORKDIR}/netdata.conf ${D}${sysconfdir}/netdata/
sed -i -e 's,@@sysconfdir,${sysconfdir},g' ${D}${sysconfdir}/netdata/netdata.conf
sed -i -e 's,@@libdir,${libexecdir},g' ${D}${sysconfdir}/netdata/netdata.conf
sed -i -e 's,@@datadir,${datadir},g' ${D}${sysconfdir}/netdata/netdata.conf
if [ "${NETDATA_ANONYMOUS}" = "enabled" ]; then
touch ${D}${sysconfdir}/netdata/.opt-out-from-anonymous-statistics
fi
install --group netdata --owner netdata --directory ${D}${localstatedir}/cache/netdata
install --group netdata --owner netdata --directory ${D}${localstatedir}/lib/netdata
chown -R netdata:netdata ${D}${datadir}/netdata/web
}
FILES:${PN} += "${localstatedir}/cache/netdata/ ${localstatedir}/lib/netdata/"
RDEPENDS:${PN} = "bash zlib"