mirrors/meta-openembedded
1
0
Fork 0
mirror of https://github.com/openembedded/meta-openembedded.git synced 2026-05-08 05:29:22 +00:00
Code Issues Projects Releases Wiki Activity

python3-blivet: upgrade 3.12.1 -> 3.13.2

Browse Source 
Changelog:
https://github.com/storaged-project/blivet/releases

1. Drop 0008-use-oe-variable-to-replace-hardcoded-dir.patch and add
   do_install:append to manually install D-Bus and systemd files:
   Upstream commit 0f0fd84d [1] removed data_files from setup.py and
   moved their installation to a Makefile target (install-dbus), but
   OE uses setuptools3_legacy which only runs setup.py install and
   does not invoke the Makefile.

2. Add missing RDEPENDS:
   - python3-dasbus: upstream replaced the internal safe_dbus module
     with the external dasbus library [2].
   - python3-pygobject: was always required (gi.repository for
     libblockdev) but missing from old recipe.
   - util-linux: blivet directly calls lsblk, mount, umount and
     blockdev via subprocess.

[1] https://github.com/storaged-project/blivet/commit/0f0fd84d
[2] https://github.com/storaged-project/blivet/commit/1e7c5409

Signed-off-by: Jiaying Song <jiaying.song.cn@windriver.com>
Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
This commit is contained in:
Jiaying Song
2026-04-13 17:29:55 +08:00
committed by Khem Raj
parent 96a803a50d
commit 3551db3839
2 changed files with 14 additions and 38 deletions
Download Patch File Download Diff File Expand all files Collapse all files
meta-python/recipes-extended/python-blivet/python3-blivet_3.13.2.bb
+47
View File
@@ -0,0 +1,47 @@
DESCRIPTION = "A python module for system storage configuration"
HOMEPAGE = "https://fedoraproject.org/wiki/blivet"
LICENSE = "LGPL-2.0-or-later"
SECTION = "devel/python"
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
SRC_URI += "\
file://0002-run_program-support-timeout.patch \
file://0003-support-infinit-timeout.patch \
file://0005-fix-incorrect-timeout-while-system-time-changed.patch \
file://0006-tweak-btrfs-packages.patch \
file://0007-invoking-mount-with-infinite-timeout.patch \
file://0009-invoking-fsck-with-infinite-timeout.patch \
file://0010-invoking-mkfs-with-infinite-timeout.patch \
file://0011-invoking-dd-with-infinite-timeout.patch \
"
SRC_URI[sha256sum] = "6d8374d05eeab513b2a26cf01267e853df7b31e13ad1a1ba7d73a856190d0518"
inherit pypi features_check systemd setuptools3_legacy
REQUIRED_DISTRO_FEATURES = "systemd"
RDEPENDS:${PN} += "python3-dasbus python3-pygobject python3-pykickstart python3-pyudev \
parted python3-pyparted multipath-tools \
lsof cryptsetup libblockdev libblockdev-bin \
libbytesize \
util-linux \
"
do_install:append() {
install -d ${D}${sysconfdir}/dbus-1/system.d
install -m 644 ${S}/dbus/blivet.conf ${D}${sysconfdir}/dbus-1/system.d/blivet.conf
install -d ${D}${datadir}/dbus-1/system-services
install -m 644 ${S}/dbus/com.redhat.Blivet0.service ${D}${datadir}/dbus-1/system-services/com.redhat.Blivet0.service
install -d ${D}${libexecdir}
install -m 755 ${S}/dbus/blivetd ${D}${libexecdir}/blivetd
install -d ${D}${systemd_system_unitdir}
install -m 644 ${S}/dbus/blivet.service ${D}${systemd_system_unitdir}/blivet.service
}
FILES:${PN} += " \
${datadir}/dbus-1/system-services \
"
SYSTEMD_AUTO_ENABLE = "disable"
SYSTEMD_SERVICE:${PN} = "blivet.service"