mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 05:49:57 +00:00
nodejs: upgrade 16.20.1 -> 16.20.2
This release contains bug fixes only. The following CVEs have been addressed: CVE-2023-32002 CVE-2023-32006 CVE-2023-32559 $ git log --oneline v16.20.1..v16.20.2 dadbde963f (tag: v16.20.2) 2023-08-09, Version 16.20.2 'Gallium' (LTS) d8ccfe9ad4 policy: handle Module.constructor and main.extensions bypass 242aaa0caa policy: disable process.binding() when enabled 40c3958a5a deps: update archs files for OpenSSL-1.1.1v a9ac9da89a deps: fix openssl crypto clean 362d4c7494 deps: upgrade openssl sources to OpenSSL_1_1_1v 7447de2794 Working on v16.20.2 https://github.com/nodejs/node/releases/tag/v16.20.2 Signed-off-by: Archana Polampalli <archana.polampalli@windriver.com> Signed-off-by: Armin Kuster <akuster808@gmail.com>
This commit is contained in:
Polampalli, Archana
committed by
Armin Kuster
Armin Kuster
parent
3e80d586ef
commit
529620141e
@@ -0,0 +1,185 @@
|
||||
DESCRIPTION = "nodeJS Evented I/O for V8 JavaScript"
|
||||
HOMEPAGE = "http://nodejs.org"
|
||||
LICENSE = "MIT & ISC & BSD-2-Clause & BSD-3-Clause & Artistic-2.0 & OpenSSL"
|
||||
LIC_FILES_CHKSUM = "file://LICENSE;md5=ab4d0d45e717c9978737499a3489e515"
|
||||
|
||||
DEPENDS = "openssl"
|
||||
DEPENDS:append:class-target = " qemu-native"
|
||||
DEPENDS:append:class-native = " c-ares-native"
|
||||
|
||||
inherit pkgconfig python3native qemu setuptools3
|
||||
|
||||
COMPATIBLE_MACHINE:armv4 = "(!.*armv4).*"
|
||||
COMPATIBLE_MACHINE:armv5 = "(!.*armv5).*"
|
||||
COMPATIBLE_MACHINE:mips64 = "(!.*mips64).*"
|
||||
|
||||
COMPATIBLE_HOST:riscv64 = "null"
|
||||
COMPATIBLE_HOST:riscv32 = "null"
|
||||
COMPATIBLE_HOST:powerpc = "null"
|
||||
|
||||
SRC_URI = "http://nodejs.org/dist/v${PV}/node-v${PV}.tar.xz \
|
||||
file://0001-Disable-running-gyp-files-for-bundled-deps.patch \
|
||||
file://0004-v8-don-t-override-ARM-CFLAGS.patch \
|
||||
file://big-endian.patch \
|
||||
file://mips-less-memory.patch \
|
||||
file://system-c-ares.patch \
|
||||
file://0001-liftoff-Correct-function-signatures.patch \
|
||||
file://0001-mips-Use-32bit-cast-for-operand-on-mips32.patch \
|
||||
file://0001-Nodejs-Fixed-pipes-DeprecationWarning.patch \
|
||||
"
|
||||
SRC_URI:append:class-target = " \
|
||||
file://0001-Using-native-binaries.patch \
|
||||
"
|
||||
SRC_URI:append:toolchain-clang:x86 = " \
|
||||
file://libatomic.patch \
|
||||
"
|
||||
SRC_URI:append:toolchain-clang:powerpc64le = " \
|
||||
file://0001-ppc64-Do-not-use-mminimal-toc-with-clang.patch \
|
||||
"
|
||||
SRC_URI[sha256sum] = "576f1a03c455e491a8d132b587eb6b3b84651fc8974bb3638433dd44d22c8f49"
|
||||
|
||||
S = "${WORKDIR}/node-v${PV}"
|
||||
|
||||
# v8 errors out if you have set CCACHE
|
||||
CCACHE = ""
|
||||
|
||||
def map_nodejs_arch(a, d):
|
||||
import re
|
||||
|
||||
if re.match('i.86$', a): return 'ia32'
|
||||
elif re.match('x86_64$', a): return 'x64'
|
||||
elif re.match('aarch64$', a): return 'arm64'
|
||||
elif re.match('(powerpc64|powerpc64le|ppc64le)$', a): return 'ppc64'
|
||||
elif re.match('powerpc$', a): return 'ppc'
|
||||
return a
|
||||
|
||||
ARCHFLAGS:arm = "${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', '--with-arm-float-abi=hard', '--with-arm-float-abi=softfp', d)} \
|
||||
${@bb.utils.contains('TUNE_FEATURES', 'neon', '--with-arm-fpu=neon', \
|
||||
bb.utils.contains('TUNE_FEATURES', 'vfpv3d16', '--with-arm-fpu=vfpv3-d16', \
|
||||
bb.utils.contains('TUNE_FEATURES', 'vfpv3', '--with-arm-fpu=vfpv3', \
|
||||
'--with-arm-fpu=vfp', d), d), d)}"
|
||||
ARCHFLAGS:append:mips = " --v8-lite-mode"
|
||||
ARCHFLAGS:append:mipsel = " --v8-lite-mode"
|
||||
ARCHFLAGS ?= ""
|
||||
|
||||
PACKAGECONFIG ??= "ares brotli icu zlib"
|
||||
|
||||
PACKAGECONFIG[ares] = "--shared-cares,,c-ares"
|
||||
PACKAGECONFIG[brotli] = "--shared-brotli,,brotli"
|
||||
PACKAGECONFIG[icu] = "--with-intl=system-icu,--without-intl,icu"
|
||||
PACKAGECONFIG[libuv] = "--shared-libuv,,libuv"
|
||||
PACKAGECONFIG[nghttp2] = "--shared-nghttp2,,nghttp2"
|
||||
PACKAGECONFIG[shared] = "--shared"
|
||||
PACKAGECONFIG[zlib] = "--shared-zlib,,zlib"
|
||||
|
||||
# We don't want to cross-compile during target compile,
|
||||
# and we need to use the right flags during host compile,
|
||||
# too.
|
||||
EXTRA_OEMAKE = "\
|
||||
CC.host='${CC}' \
|
||||
CFLAGS.host='${CPPFLAGS} ${CFLAGS}' \
|
||||
CXX.host='${CXX}' \
|
||||
CXXFLAGS.host='${CPPFLAGS} ${CXXFLAGS}' \
|
||||
LDFLAGS.host='${LDFLAGS}' \
|
||||
AR.host='${AR}' \
|
||||
\
|
||||
builddir_name=./ \
|
||||
"
|
||||
|
||||
python do_unpack() {
|
||||
import shutil
|
||||
|
||||
bb.build.exec_func('base_do_unpack', d)
|
||||
shutil.rmtree(d.getVar('S') + '/deps/openssl', True)
|
||||
if 'ares' in d.getVar('PACKAGECONFIG'):
|
||||
shutil.rmtree(d.getVar('S') + '/deps/cares', True)
|
||||
if 'brotli' in d.getVar('PACKAGECONFIG'):
|
||||
shutil.rmtree(d.getVar('S') + '/deps/brotli', True)
|
||||
if 'libuv' in d.getVar('PACKAGECONFIG'):
|
||||
shutil.rmtree(d.getVar('S') + '/deps/uv', True)
|
||||
if 'nghttp2' in d.getVar('PACKAGECONFIG'):
|
||||
shutil.rmtree(d.getVar('S') + '/deps/nghttp2', True)
|
||||
if 'zlib' in d.getVar('PACKAGECONFIG'):
|
||||
shutil.rmtree(d.getVar('S') + '/deps/zlib', True)
|
||||
}
|
||||
|
||||
# V8's JIT infrastructure requires binaries such as mksnapshot and
|
||||
# mkpeephole to be run in the host during the build. However, these
|
||||
# binaries must have the same bit-width as the target (e.g. a x86_64
|
||||
# host targeting ARMv6 needs to produce a 32-bit binary). Instead of
|
||||
# depending on a third Yocto toolchain, we just build those binaries
|
||||
# for the target and run them on the host with QEMU.
|
||||
python do_create_v8_qemu_wrapper () {
|
||||
"""Creates a small wrapper that invokes QEMU to run some target V8 binaries
|
||||
on the host."""
|
||||
qemu_libdirs = [d.expand('${STAGING_DIR_HOST}${libdir}'),
|
||||
d.expand('${STAGING_DIR_HOST}${base_libdir}')]
|
||||
qemu_cmd = qemu_wrapper_cmdline(d, d.getVar('STAGING_DIR_HOST', True),
|
||||
qemu_libdirs)
|
||||
wrapper_path = d.expand('${B}/v8-qemu-wrapper.sh')
|
||||
with open(wrapper_path, 'w') as wrapper_file:
|
||||
wrapper_file.write("""#!/bin/sh
|
||||
|
||||
# This file has been generated automatically.
|
||||
# It invokes QEMU to run binaries built for the target in the host during the
|
||||
# build process.
|
||||
|
||||
%s "$@"
|
||||
""" % qemu_cmd)
|
||||
os.chmod(wrapper_path, 0o755)
|
||||
}
|
||||
|
||||
do_create_v8_qemu_wrapper[dirs] = "${B}"
|
||||
addtask create_v8_qemu_wrapper after do_configure before do_compile
|
||||
|
||||
LDFLAGS:append:x86 = " -latomic"
|
||||
|
||||
# Node is way too cool to use proper autotools, so we install two wrappers to forcefully inject proper arch cflags to workaround gypi
|
||||
do_configure () {
|
||||
export LD="${CXX}"
|
||||
GYP_DEFINES="${GYP_DEFINES}" export GYP_DEFINES
|
||||
# $TARGET_ARCH settings don't match --dest-cpu settings
|
||||
python3 configure.py --prefix=${prefix} --cross-compiling \
|
||||
--shared-openssl \
|
||||
--without-dtrace \
|
||||
--without-etw \
|
||||
--dest-cpu="${@map_nodejs_arch(d.getVar('TARGET_ARCH'), d)}" \
|
||||
--dest-os=linux \
|
||||
--libdir=${D}${libdir} \
|
||||
${ARCHFLAGS} \
|
||||
${PACKAGECONFIG_CONFARGS}
|
||||
}
|
||||
|
||||
do_compile () {
|
||||
export LD="${CXX}"
|
||||
install -D ${B}/v8-qemu-wrapper.sh ${B}/out/Release/v8-qemu-wrapper.sh
|
||||
oe_runmake BUILDTYPE=Release
|
||||
}
|
||||
|
||||
do_install () {
|
||||
oe_runmake install DESTDIR=${D}
|
||||
}
|
||||
|
||||
BINARIES = " \
|
||||
bytecode_builtins_list_generator \
|
||||
${@bb.utils.contains('PACKAGECONFIG', 'icu', 'gen-regexp-special-case', '', d)} \
|
||||
mkcodecache \
|
||||
node_mksnapshot \
|
||||
torque \
|
||||
"
|
||||
|
||||
do_install:append:class-native() {
|
||||
# Install the native binaries to provide it within sysroot for the target compilation
|
||||
install -d ${D}${bindir}
|
||||
(cd ${S}/out/Release && install ${BINARIES} ${D}${bindir})
|
||||
}
|
||||
|
||||
PACKAGES =+ "${PN}-npm"
|
||||
FILES:${PN}-npm = "${nonarch_libdir}/node_modules ${bindir}/npm ${bindir}/npx"
|
||||
RDEPENDS:${PN}-npm = "bash python3-core python3-shell python3-datetime \
|
||||
python3-misc python3-multiprocessing"
|
||||
|
||||
PACKAGES =+ "${PN}-systemtap"
|
||||
FILES:${PN}-systemtap = "${datadir}/systemtap"
|
||||
|
||||
BBCLASSEXTEND = "native"
|
||||
Reference in New Issue
Block a user