python3-tokenize-rt: add at v6.2.0

A wrapper around the stdlib `tokenize` which roundtrips.

Dependency for python3-time-machine ptests.
Use git fetcher so we have tests/ and testing/resources/ for ptest.

Testsuite summary
TOTAL: 45
PASS: 45
SKIP: 0
XFAIL: 0
FAIL: 0
XPASS: 0
ERROR: 0
DURATION: 8

Signed-off-by: Tim Orling <tim.orling@konsulko.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

meta-python/conf/include/ptest-packagelists-meta-python.inc

@@ -105,6 +105,7 @@ PTESTS_FAST_META_PYTHON = "\
     python3-starlette \
     python3-tblib \
     python3-tenacity \
+    python3-tokenize-rt \
     python3-tomli-w \
     python3-tomlkit \
     python3-trustme \

meta-python/recipes-devtools/python/python3-tokenize-rt_6.2.0.bb

@@ -0,0 +1,21 @@
+SUMMARY = "A wrapper around the stdlib `tokenize` which roundtrips."
+HOMEPAGE = "https://github.com/asottile/tokenize-rt"
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=5fd324061c581b8d45b8cb18c560a543"
+
+SRCREV = "1582bcf0259d183259da1761444c6fc73fa7ad9a"
+PYPI_SRC_URI = "git://github.com/asottile/tokenize-rt.git;protocol=https;branch=main;tag=v${PV};destsuffix=tokenize_rt-${PV}"
+
+inherit pypi setuptools3 ptest-python-pytest
+
+RDEPENDS:${PN} += "python3-core"
+
+PYPI_PACKAGE = "tokenize_rt"
+UPSTREAM_CHECK_PYPI_PACKAGE = "${PYPI_PACKAGE}"
+
+do_install_ptest:append() {
+    install -d ${D}${PTEST_PATH}/testing/resources
+    cp -rf ${S}/testing/resources/* ${D}${PTEST_PATH}/testing/resources/
+    install -d ${D}${PTEST_PATH}/tests
+    cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
+}