python3-m2crypto: upgrade 0.48.0 -> 0.49.0

Changelog:
==========
- defer unavailable ENGINE constant lookup
- fixes problematic behaviour of pkcs11-provider
- support TLS 1.0 contexts with modern OpenSSL
- use Python 3 C APIs in handwritten SWIG code
- feat: Add AES-GCM (AEAD) support to M2Crypto
- remove Black configuration from setup.cfg
- release X509V3 config with its context
- keep IOBuffer chains alive until destruction
- test: free low-level OpenSSL objects in leak tests
- avoid leaking X509V3 extension config
- free RSA exponent on modulus conversion failure
- free replaced EVP digest contexts
- wrap created X509 name entries with ownership
- own ASN1 values created from Python data
- own PKCS7 certificate stack copies
- release BIOs on explicit close
- Add AuthorityKeyIdentifier extension support

Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>

meta-python/recipes-devtools/python/python3-m2crypto_0.49.0.bb

@@ -0,0 +1,58 @@
+SUMMARY = "A Python crypto and SSL toolkit"
+HOMEPAGE = "https://gitlab.com/m2crypto/m2crypto"
+
+LICENSE = "BSD-2-Clause"
+LIC_FILES_CHKSUM = "file://LICENSES/BSD-2-Clause.txt;md5=8099b0e569f862ece05740aef06c82a2"
+
+SRC_URI[sha256sum] = "604b9cdd7c1bb9e73e54a189643d56d08bf841691775122962430ee2ca3506fe"
+
+SRC_URI += "file://0001-setup.py-Make-the-cmd-available.patch"
+SRC_URI += "file://0002-_m2crypto.i-add-py2-py3-C-API-compat-macros.patch"
+
+CVE_STATUS[CVE-2009-0127] = "disputed: upstream claims there is no bug"
+CVE_STATUS[CVE-2020-25657] = "fixed-version: the used version (0.46.2) contains the fix already"
+
+inherit pypi siteinfo python_setuptools_build_meta
+
+DEPENDS += "python3-wheel-native"
+
+DEPENDS += "openssl swig-native"
+RDEPENDS:${PN} += "\
+  python3-datetime \
+  python3-setuptools \
+  python3-logging \
+  python3-netclient \
+  python3-netserver \
+  python3-numbers \
+  python3-xmlrpc \
+"
+
+DISTUTILS_BUILD_ARGS += "build_ext --openssl=${STAGING_EXECPREFIXDIR} -I${STAGING_INCDIR}"
+DISTUTILS_INSTALL_ARGS += "build_ext --openssl=${STAGING_EXECPREFIXDIR}"
+
+SWIG_FEATURES ?= "-D__${HOST_ARCH}__ ${@['-D__ILP32__','-D__LP64__'][d.getVar('SITEINFO_BITS') != '32']} -DOPENSSL_NO_FILENAMES"
+
+SWIG_FEATURES:append:riscv64 = " -D__SIZEOF_POINTER__=${SITEINFO_BITS}/8 -D__riscv_xlen=${SITEINFO_BITS}"
+SWIG_FEATURES:append:riscv32 = " -D__SIZEOF_POINTER__=${SITEINFO_BITS}/8 -D__riscv_xlen=${SITEINFO_BITS}"
+SWIG_FEATURES:append:mipsarch = " -D_MIPS_SZPTR=${SITEINFO_BITS}"
+SWIG_FEATURES:append:powerpc64le = " -D__powerpc64__"
+SWIG_FEATURES:append:x86 = " -D__i386__"
+SWIG_FEATURES:append:x32 = " -D__ILP32__"
+
+export SWIG_FEATURES
+
+export STAGING_DIR
+
+do_configure:prepend:class-target() {
+    # workaround for https://github.com/swiftlang/swift/issues/69311
+    sed -i "/sys\/types.h/d" ${RECIPE_SYSROOT}${includedir}/openssl/e_os2.h
+}
+
+do_install:append() {
+    rm -f ${D}${PYTHON_SITEPACKAGES_DIR}/M2Crypto/SSL/__pycache__/*.cpython-*.pyc
+    rm -f ${D}${PYTHON_SITEPACKAGES_DIR}/M2Crypto/__pycache__/*.cpython-*.pyc
+}
+
+CVE_PRODUCT = "m2crypto"
+
+BBCLASSEXTEND = "native"