ruby: Update to 2.2.2

Includes among other things: CVE-2015-1855: Ruby OpenSSL Hostname Verification

for more info see:
http://svn.ruby-lang.org/repos/ruby/tags/v2_2_2/ChangeLog

also, fixed runtime error.
only include "enable-wide-getaddrinfo" if IVP6 is enabled in disto feature
otherwise 'gem install rails' throws an error for the missing symbol 'getipnodebyname'.

Signed-off-by: Armin Kuster <akuster808@gmail.com>

meta-ruby/recipes-devtools/ruby/ruby_2.2.2.bb

@@ -0,0 +1,41 @@
+require ruby.inc
+
+SRC_URI[md5sum] = "326e99ddc75381c7b50c85f7089f3260"
+SRC_URI[sha256sum] = "5ffc0f317e429e6b29d4a98ac521c3ce65481bfd22a8cf845fa02a7b113d9b44"
+
+# it's unknown to configure script, but then passed to extconf.rb
+# maybe it's not really needed as we're hardcoding the result with
+# 0001-socket-extconf-hardcode-wide-getaddr-info-test-outco.patch
+UNKNOWN_CONFIGURE_WHITELIST += "--enable-wide-getaddrinfo"
+
+PACKAGECONFIG ??= ""
+PACKAGECONFIG += "${@bb.utils.contains('DISTRO_FEATURES', 'ipv6', 'ipv6', '', d)}"
+
+PACKAGECONFIG[valgrind] = "--with-valgrind=yes, --with-valgrind=no, valgrind"
+PACKAGECONFIG[gpm] = "--with-gmp=yes, --with-gmp=no, gmp"
+PACKAGECONFIG[ipv6] = ",--enable-wide-getaddrinfo,"
+
+EXTRA_OECONF = "\
+    --disable-versioned-paths \
+    --disable-rpath \
+    --enable-shared \
+    --enable-load-relative \
+"
+
+EXTRA_OEMAKE = " \
+    LIBRUBYARG='-lruby-static' \
+"
+
+do_install() {
+    oe_runmake 'DESTDIR=${D}' install
+}
+
+FILES_${PN} += "${datadir}/rubygems \
+                ${datadir}/ri"
+
+FILES_${PN}-dbg += "${libdir}/ruby/*/.debug \
+                    ${libdir}/ruby/*/*/.debug \
+                    ${libdir}/ruby/*/*/*/.debug \
+                    ${libdir}/ruby/*/*/*/*/.debug"
+
+BBCLASSEXTEND = "native"