python3-pandas: upgrade 2.0.3 -> 2.2.2

pandas 2.2.2 is the first version compatible with numpy 2.0.x.

The package now uses meson as the build backend, so change the recipe to
inherit that.

Its pyproject.toml pins required versions for Cython and meson, but
newer upstream pandas releases are using different versions and
compatibility strings, so just add an OE-specific patch to relax the
requirements a bit for us.

Changelog: https://pandas.pydata.org/pandas-docs/version/2.2.2/whatsnew/v2.2.2.html

Signed-off-by: Trevor Gamblin <tgamblin@baylibre.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

meta-python/recipes-devtools/python/python3-pandas_2.2.2.bb

@@ -0,0 +1,42 @@
+SUMMARY  = "pandas library for high-performance data analysis tools"
+DESCRIPTION = "pandas is an open source, BSD-licensed library providing \
+high-performance, easy-to-use data structures and data analysis tools for \
+the Python programming language."
+HOMEPAGE = "http://pandas.pydata.org/"
+LICENSE = "BSD-3-Clause"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=cb819092901ddb13a7d0a4f5e05f098a"
+
+SRC_URI += " \
+            file://0001-pyproject.toml-don-t-pin-dependency-versions.patch \
+            "
+
+SRC_URI[sha256sum] = "9e79019aba43cb4fda9e4d983f8e88ca0373adbb697ae9c6c43093218de28b54"
+
+inherit pypi python_mesonpy
+
+DEPENDS += " \
+    python3-cython-native \
+    python3-numpy-native \
+    python3-versioneer-native \
+"
+
+PACKAGESPLITFUNCS =+ "fix_cythonized_sources"
+
+fix_cythonized_sources() {
+	for f in `grep -l -r -e '\/* Generated by Cython.*/$' ${PKGD}${TARGET_DBGSRC_DIR}`; do
+		if [ -e $f ]; then
+			sed -i -e 's#${RECIPE_SYSROOT_NATIVE}##g' $f
+		fi
+	done
+}
+
+CFLAGS:append:toolchain-clang = " -Wno-error=deprecated-declarations"
+
+RDEPENDS:${PN} += " \
+    python3-json \
+    python3-numpy \
+    python3-dateutil \
+    python3-dateutil-zoneinfo \
+    python3-pytz \
+    python3-profile \
+"