mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 17:59:59 +00:00
nodejs: 12.20.2 -> 12.21.0
Fixes :
- CVE-2021-22883
- CVE-2021-22884
- CVE-2021-23840
Signed-off-by: Clément Péron <peron.clem@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
(cherry picked from commit 02feb1d932)
[12.x LTS version]
Signed-off-by: Armin Kuster <akuster808@gmail.com>
This commit is contained in:
Clément Péron
committed by
Armin Kuster
Armin Kuster
parent
1ea5c51d98
commit
d460525cd5
@@ -0,0 +1,161 @@
|
||||
DESCRIPTION = "nodeJS Evented I/O for V8 JavaScript"
|
||||
HOMEPAGE = "http://nodejs.org"
|
||||
LICENSE = "MIT & BSD & Artistic-2.0"
|
||||
LIC_FILES_CHKSUM = "file://LICENSE;md5=8c66ff8861d9f96076a7cb61e3d75f54"
|
||||
|
||||
DEPENDS = "openssl"
|
||||
DEPENDS_append_class-target = " nodejs-native"
|
||||
|
||||
inherit pkgconfig python3native
|
||||
|
||||
COMPATIBLE_MACHINE_armv4 = "(!.*armv4).*"
|
||||
COMPATIBLE_MACHINE_armv5 = "(!.*armv5).*"
|
||||
COMPATIBLE_MACHINE_mips64 = "(!.*mips64).*"
|
||||
|
||||
COMPATIBLE_HOST_riscv64 = "null"
|
||||
COMPATIBLE_HOST_riscv32 = "null"
|
||||
|
||||
SRC_URI = "http://nodejs.org/dist/v${PV}/node-v${PV}.tar.xz \
|
||||
file://0001-Disable-running-gyp-files-for-bundled-deps.patch \
|
||||
file://0003-Install-both-binaries-and-use-libdir.patch \
|
||||
file://0004-v8-don-t-override-ARM-CFLAGS.patch \
|
||||
file://big-endian.patch \
|
||||
file://mips-warnings.patch \
|
||||
file://0001-Remove-use-of-register-r7-because-llvm-now-issues-an.patch \
|
||||
"
|
||||
SRC_URI_append_class-target = " \
|
||||
file://0002-Using-native-binaries.patch \
|
||||
"
|
||||
SRC_URI[sha256sum] = "052f37ace6f569b513b5a1154b2a45d3c4d8b07d7d7c807b79f1566db61e979d"
|
||||
|
||||
S = "${WORKDIR}/node-v${PV}"
|
||||
|
||||
# v8 errors out if you have set CCACHE
|
||||
CCACHE = ""
|
||||
|
||||
def map_nodejs_arch(a, d):
|
||||
import re
|
||||
|
||||
if re.match('i.86$', a): return 'ia32'
|
||||
elif re.match('x86_64$', a): return 'x64'
|
||||
elif re.match('aarch64$', a): return 'arm64'
|
||||
elif re.match('(powerpc64|ppc64le)$', a): return 'ppc64'
|
||||
elif re.match('powerpc$', a): return 'ppc'
|
||||
return a
|
||||
|
||||
ARCHFLAGS_arm = "${@bb.utils.contains('TUNE_FEATURES', 'callconvention-hard', '--with-arm-float-abi=hard', '--with-arm-float-abi=softfp', d)} \
|
||||
${@bb.utils.contains('TUNE_FEATURES', 'neon', '--with-arm-fpu=neon', \
|
||||
bb.utils.contains('TUNE_FEATURES', 'vfpv3d16', '--with-arm-fpu=vfpv3-d16', \
|
||||
bb.utils.contains('TUNE_FEATURES', 'vfpv3', '--with-arm-fpu=vfpv3', \
|
||||
'--with-arm-fpu=vfp', d), d), d)}"
|
||||
GYP_DEFINES_append_mipsel = " mips_arch_variant='r1' "
|
||||
ARCHFLAGS ?= ""
|
||||
|
||||
PACKAGECONFIG ??= "ares brotli icu zlib"
|
||||
|
||||
PACKAGECONFIG[ares] = "--shared-cares,,c-ares"
|
||||
PACKAGECONFIG[brotli] = "--shared-brotli,,brotli"
|
||||
PACKAGECONFIG[icu] = "--with-intl=system-icu,--without-intl,icu"
|
||||
PACKAGECONFIG[libuv] = "--shared-libuv,,libuv"
|
||||
PACKAGECONFIG[nghttp2] = "--shared-nghttp2,,nghttp2"
|
||||
PACKAGECONFIG[shared] = "--shared"
|
||||
PACKAGECONFIG[zlib] = "--shared-zlib,,zlib"
|
||||
|
||||
# We don't want to cross-compile during target compile,
|
||||
# and we need to use the right flags during host compile,
|
||||
# too.
|
||||
EXTRA_OEMAKE = "\
|
||||
CC.host='${CC}' \
|
||||
CFLAGS.host='${CPPFLAGS} ${CFLAGS}' \
|
||||
CXX.host='${CXX}' \
|
||||
CXXFLAGS.host='${CPPFLAGS} ${CXXFLAGS}' \
|
||||
LDFLAGS.host='${LDFLAGS}' \
|
||||
AR.host='${AR}' \
|
||||
\
|
||||
builddir_name=./ \
|
||||
"
|
||||
|
||||
python do_unpack() {
|
||||
import shutil
|
||||
|
||||
bb.build.exec_func('base_do_unpack', d)
|
||||
|
||||
shutil.rmtree(d.getVar('S') + '/deps/openssl', True)
|
||||
if 'ares' in d.getVar('PACKAGECONFIG'):
|
||||
shutil.rmtree(d.getVar('S') + '/deps/cares', True)
|
||||
if 'brotli' in d.getVar('PACKAGECONFIG'):
|
||||
shutil.rmtree(d.getVar('S') + '/deps/brotli', True)
|
||||
if 'libuv' in d.getVar('PACKAGECONFIG'):
|
||||
shutil.rmtree(d.getVar('S') + '/deps/uv', True)
|
||||
if 'nghttp2' in d.getVar('PACKAGECONFIG'):
|
||||
shutil.rmtree(d.getVar('S') + '/deps/nghttp2', True)
|
||||
if 'zlib' in d.getVar('PACKAGECONFIG'):
|
||||
shutil.rmtree(d.getVar('S') + '/deps/zlib', True)
|
||||
}
|
||||
|
||||
# Node is way too cool to use proper autotools, so we install two wrappers to forcefully inject proper arch cflags to workaround gypi
|
||||
do_configure () {
|
||||
export LD="${CXX}"
|
||||
GYP_DEFINES="${GYP_DEFINES}" export GYP_DEFINES
|
||||
# $TARGET_ARCH settings don't match --dest-cpu settings
|
||||
python3 configure.py --prefix=${prefix} --cross-compiling --without-snapshot --shared-openssl \
|
||||
--without-dtrace \
|
||||
--without-etw \
|
||||
--dest-cpu="${@map_nodejs_arch(d.getVar('TARGET_ARCH'), d)}" \
|
||||
--dest-os=linux \
|
||||
--libdir=${D}${libdir} \
|
||||
${ARCHFLAGS} \
|
||||
${PACKAGECONFIG_CONFARGS}
|
||||
}
|
||||
|
||||
do_compile () {
|
||||
export LD="${CXX}"
|
||||
oe_runmake BUILDTYPE=Release
|
||||
}
|
||||
|
||||
do_install () {
|
||||
oe_runmake install DESTDIR=${D}
|
||||
|
||||
# wasn't updated since 2009 and is the only thing requiring python2 in runtime
|
||||
# ERROR: nodejs-12.14.1-r0 do_package_qa: QA Issue: /usr/lib/node_modules/npm/node_modules/node-gyp/gyp/samples/samples contained in package nodejs-npm requires /usr/bin/python, but no providers found in RDEPENDS_nodejs-npm? [file-rdeps]
|
||||
rm -f ${D}${exec_prefix}/lib/node_modules/npm/node_modules/node-gyp/gyp/samples/samples
|
||||
}
|
||||
|
||||
do_install_append_class-native() {
|
||||
# use node from PATH instead of absolute path to sysroot
|
||||
# node-v0.10.25/tools/install.py is using:
|
||||
# shebang = os.path.join(node_prefix, 'bin/node')
|
||||
# update_shebang(link_path, shebang)
|
||||
# and node_prefix can be very long path to bindir in native sysroot and
|
||||
# when it exceeds 128 character shebang limit it's stripped to incorrect path
|
||||
# and npm fails to execute like in this case with 133 characters show in log.do_install:
|
||||
# updating shebang of /home/jenkins/workspace/build-webos-nightly/device/qemux86/label/open-webos-builder/BUILD-qemux86/work/x86_64-linux/nodejs-native/0.10.15-r0/image/home/jenkins/workspace/build-webos-nightly/device/qemux86/label/open-webos-builder/BUILD-qemux86/sysroots/x86_64-linux/usr/bin/npm to /home/jenkins/workspace/build-webos-nightly/device/qemux86/label/open-webos-builder/BUILD-qemux86/sysroots/x86_64-linux/usr/bin/node
|
||||
# /usr/bin/npm is symlink to /usr/lib/node_modules/npm/bin/npm-cli.js
|
||||
# use sed on npm-cli.js because otherwise symlink is replaced with normal file and
|
||||
# npm-cli.js continues to use old shebang
|
||||
sed "1s^.*^#\!/usr/bin/env node^g" -i ${D}${exec_prefix}/lib/node_modules/npm/bin/npm-cli.js
|
||||
|
||||
# Install the native binaries to provide it within sysroot for the target compilation
|
||||
install -d ${D}${bindir}
|
||||
install -m 0755 ${S}/out/Release/torque ${D}${bindir}/torque
|
||||
install -m 0755 ${S}/out/Release/bytecode_builtins_list_generator ${D}${bindir}/bytecode_builtins_list_generator
|
||||
if ${@bb.utils.contains('PACKAGECONFIG','icu','true','false',d)}; then
|
||||
install -m 0755 ${S}/out/Release/gen-regexp-special-case ${D}${bindir}/gen-regexp-special-case
|
||||
fi
|
||||
install -m 0755 ${S}/out/Release/mkcodecache ${D}${bindir}/mkcodecache
|
||||
install -m 0755 ${S}/out/Release/node_mksnapshot ${D}${bindir}/node_mksnapshot
|
||||
}
|
||||
|
||||
do_install_append_class-target() {
|
||||
sed "1s^.*^#\!${bindir}/env node^g" -i ${D}${exec_prefix}/lib/node_modules/npm/bin/npm-cli.js
|
||||
}
|
||||
|
||||
PACKAGES =+ "${PN}-npm"
|
||||
FILES_${PN}-npm = "${exec_prefix}/lib/node_modules ${bindir}/npm ${bindir}/npx"
|
||||
RDEPENDS_${PN}-npm = "bash python3-core python3-shell python3-datetime \
|
||||
python3-misc python3-multiprocessing"
|
||||
|
||||
PACKAGES =+ "${PN}-systemtap"
|
||||
FILES_${PN}-systemtap = "${datadir}/systemtap"
|
||||
|
||||
BBCLASSEXTEND = "native"
|
||||
Reference in New Issue
Block a user