python3-gunicorn: upgrade 26.1.0 -> 26.2.0

Changelog:
https://github.com/benoitc/gunicorn/releases/tag/26.2.2

Signed-off-by: Ankur Tyagi <ankur.tyagi85@gmail.com>
Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>

meta-python/recipes-devtools/python/python3-gunicorn_26.2.0.bb

@@ -0,0 +1,43 @@
+SUMMARY = "WSGI HTTP Server for UNIX"
+
+LICENSE = "MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=5dc9171ccd8fcbd7827c850148b3ca98"
+
+SRC_URI[sha256sum] = "62b864895d9ebff0b2f9867ba04fe811c93121596540830c9c916d0769668447"
+
+inherit pypi python_setuptools_build_meta ptest
+
+CVE_PRODUCT = "gunicorn"
+
+SRC_URI += " \
+	file://run-ptest \
+"
+
+# python-misc for wsgiref
+RDEPENDS:${PN}-ptest += " \
+    bash \
+    python3-eventlet \
+    python3-gevent \
+    python3-misc \
+    python3-multiprocessing \
+    python3-pytest \
+    python3-pytest-asyncio \
+    python3-unittest-automake-output \
+"
+
+do_install_ptest() {
+	install -d ${D}${PTEST_PATH}/tests
+	cp -rf ${S}/tests/* ${D}${PTEST_PATH}/tests/
+	# tests/docker/* are docker-compose/Dockerfile-driven integration tests
+	# requiring a Docker daemon, which the ptest QEMU environment doesn't have
+	rm -rf ${D}${PTEST_PATH}/tests/docker
+	# upstream's pyproject.toml sets asyncio_mode=auto for the async tests
+	# under tests/dirty and tests/ctl; provide just that bit without pulling
+	# in the rest of upstream's addopts (e.g. --cov=gunicorn)
+	cat > ${D}${PTEST_PATH}/pytest.ini <<EOF
+[pytest]
+asyncio_mode = auto
+EOF
+}
+
+RDEPENDS:${PN} += "python3-setuptools python3-fcntl"