octave: upgrade 4.4.1 -> 6.4.0 and overhaul recipe

Complete rework of recipe was done with two targets in mind:
* Do not disappoint users on this project - it is a treasure for mathians
* Do not over-complicate recipe unnecessarily

Signed-off-by: Andreas Müller <schnitzeltony@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>

meta-oe/recipes-devtools/octave/octave_4.4.1.bb

@@ -1,40 +0,0 @@
-DESCRIPTION = "High-level language, primarily intended for numerical computations"
-HOMEPAGE = "http://www.gnu.org/software/octave/"
-SECTION = "math"
-
-LICENSE = "GPL-3.0-only"
-LIC_FILES_CHKSUM = "file://COPYING;md5=1ebbd3e34237af26da5dc08a4e440464"
-
-DEPENDS = "gperf-native texinfo lapack pcre readline"
-
-inherit autotools pkgconfig texinfo gettext mime-xdg
-
-EXTRA_OECONF = "--disable-java --disable-docs"
-
-SRC_URI = "${GNU_MIRROR}/octave/${BPN}-${PV}.tar.gz \
-           file://fix-blas-library-integer-size.patch \
-"
-
-SRC_URI[md5sum] = "b43bd5f4309a0c048c91af10cf8e8674"
-SRC_URI[sha256sum] = "09fbd0f212f4ef21e53f1d9c41cf30ce3d7f9450fb44911601e21ed64c67ae97"
-
-do_compile:prepend() {
-	for folder in "liboctave/operators liboctave/numeric liboctave/array liboctave/util"; do
-		mkdir -p ${B}/${folder}
-	done
-}
-
-PACKAGES =+ " octave-common liboctave liboctave-dev liboctave-dbg"
-
-FILES:${PN} = "${bindir}/* ${sbindir}/* ${libexecdir}/* ${datadir}/${PN} \
-            ${libdir}/${PN}/${PV}/oct ${libdir}/${PN}/${PV}/site  \
-            ${libdir}/${PN}/site ${datadir}/applications ${datadir}/metainfo"
-FILES:${PN}-common = "${datadir}/icons"
-
-FILES:liboctave = "${libdir}/${PN}/${PV}/lib*${SOLIBS}"
-FILES:liboctave-dev = "${libdir}/${PN}/${PV}/lib*${SOLIBSDEV}"
-FILES:liboctave-dbg = "${libdir}/${PN}/${PV}/.debug"
-
-FILES:${PN}-dbg = "${bindir}/.debug ${libdir}/${PN}/${PV}/oct/${TARGET_SYS}/.debug"
-
-EXCLUDE_FROM_WORLD = "1"

meta-oe/recipes-devtools/octave/octave_6.4.0.bb

@@ -0,0 +1,52 @@
+SUMMARY = "High-level language, primarily intended for numerical computations"
+HOMEPAGE = "http://www.gnu.org/software/octave/"
+SECTION = "math"
+
+LICENSE = "GPL-3.0-only"
+LIC_FILES_CHKSUM = "file://COPYING;md5=1ebbd3e34237af26da5dc08a4e440464"
+
+# To build, add 'FORTRAN:forcevariable = ",fortran"' to your local.conf (or use
+# meta-mortsgna as distro :)
+
+DEPENDS = " \
+    gperf-native \
+    libglu \
+    lapack \
+    fftw \
+    curl \
+    freetype \
+    fontconfig \
+    texinfo \
+    pcre \
+    readline \
+    fltk \
+    hdf5 \
+    libsndfile1 \
+"
+
+inherit autotools pkgconfig texinfo gettext gtk-icon-cache mime-xdg features_check
+
+REQUIRED_DISTRO_FEATURES = "x11 opengl"
+
+SRC_URI = " \
+    ${GNU_MIRROR}/octave/${BPN}-${PV}.tar.gz \
+    file://fix-blas-library-integer-size.patch \
+"
+SRC_URI[sha256sum] = "b48f33d4fceaf394cfbea73a8c850000936d83a41739a24f7568b5b0a7b39acd"
+
+EXTRA_OECONF = " \
+    --disable-java \
+    --disable-docs \
+"
+
+do_compile:prepend() {
+	for folder in "liboctave/operators liboctave/numeric liboctave/array liboctave/util"; do
+		mkdir -p ${B}/${folder}
+	done
+}
+
+FILES:${PN} += "${datadir}/metainfo"
+FILES:${PN}-dev += "${libdir}/${BPN}/${PV}/lib*${SOLIBSDEV}"
+
+# fortran is not enabled by default
+EXCLUDE_FROM_WORLD = "1"