phpmyadmin: add new recipe

Add new recipe for phpMyAdmin 3.5.2.2, borrowing the apache.conf file
from Debian (with the addition of "Require all granted" to enable
access).

Signed-off-by: Paul Eggleton <paul.eggleton@linux.intel.com>

meta-webserver/recipes-php/phpmyadmin/phpmyadmin_3.5.2.2.bb

@@ -0,0 +1,30 @@
+SUMMARY = "Web-based MySQL administration interface"
+HOMEPAGE = "http://www.phpmyadmin.net"
+# Main code is GPLv2, libraries/tcpdf is under LGPLv3, js/jquery is under MIT
+LICENSE = "GPLv2 & LGPLv3 & MIT"
+LIC_FILES_CHKSUM = "file://LICENSE;md5=eb723b61539feef013de476e68b5c50a \
+                    file://libraries/tcpdf/LICENSE.TXT;md5=5c87b66a5358ebcc495b03e0afcd342c"
+
+PR = "r0"
+
+SRC_URI = "${SOURCEFORGE_MIRROR}/phpmyadmin/phpMyAdmin/${PV}/phpMyAdmin-${PV}-all-languages.tar.xz \
+           file://apache.conf"
+
+SRC_URI[md5sum] = "3f8993fe0f2fee1a022768278c6a270b"
+SRC_URI[sha256sum] = "d02de081c522d3026f4a8418538f7ff05adf280afa404851a5f7f4ef895b4a7d"
+
+S = "${WORKDIR}/phpMyAdmin-${PV}-all-languages"
+
+inherit allarch
+
+do_install() {
+	install -d ${D}${datadir}/${PN}
+	cp -a * ${D}${datadir}/${PN}
+
+	install -d ${D}${sysconfdir}/apache2/conf.d
+	install -m 0644 ${WORKDIR}/apache.conf ${D}${sysconfdir}/apache2/conf.d/phpmyadmin.conf
+}
+
+FILES_${PN} = "${datadir}/${PN} \
+               ${sysconfdir}/apache2/conf.d"
+