libsdl 1.2.14: import from OE rev 58b79786c6

Signed-off-by: Koen Kooi <koen@dominion.thruhere.net>

meta-oe/recipes-graphics/libsdl/libsdl-1.2.14.inc

@@ -0,0 +1,28 @@
+DESCRIPTION = "Simple DirectMedia Layer (DirectFB and Framebuffer support)"
+SECTION = "libs"
+PRIORITY = "optional"
+LICENSE = "LGPLv2.1"
+LIC_FILES_CHKSUM = "file://COPYING;md5=27818cd7fd83877a8e3ef82b82798ef4"
+
+DEPENDS = "alsa-lib"
+PROVIDES = "virtual/libsdl"
+INC_PR = "r0"
+
+SRC_URI = "http://www.libsdl.org/release/SDL-${PV}.tar.gz"
+SRC_URI[md5sum] = "e52086d1b508fa0b76c52ee30b55bec4"
+SRC_URI[sha256sum] = "5d927e287034cb6bb0ebccfa382cb1d185cb113c8ab5115a0759798642eed9b6"
+
+S = "${WORKDIR}/SDL-${PV}"
+
+inherit autotools lib_package binconfig pkgconfig
+
+EXTRA_AUTORECONF += "--include=acinclude --exclude=autoheader"
+
+do_configure_prepend () {
+        # Remove old libtool macros.
+        MACROS="libtool.m4 lt~obsolete.m4 ltoptions.m4 ltsugar.m4 ltversion.m4"
+        for i in ${MACROS}; do
+               rm -f acinclude/$i
+        done
+	export SYSROOT=$PKG_CONFIG_SYSROOT_DIR
+}

meta-oe/recipes-graphics/libsdl/libsdl-x11_1.2.14.bb

@@ -0,0 +1,18 @@
+require libsdl-1.2.14.inc
+
+DEPENDS += "virtual/libgl virtual/libx11 libxext tslib"
+DEPENDS_avr32 += "alsa-lib virtual/libx11 libxext tslib"
+
+PR = "${INC_PR}.0"
+
+EXTRA_OECONF = " \
+  --disable-static --disable-debug --enable-cdrom --enable-threads --enable-timers --enable-endian \
+  --enable-file --enable-oss --enable-alsa --disable-esd --disable-arts \
+  --disable-diskaudio --disable-nas --disable-esd-shared --disable-esdtest \
+  --disable-mintaudio --disable-nasm --enable-video-x11 --disable-video-dga \
+  --enable-video-fbcon --disable-video-directfb --disable-video-ps2gs \
+  --disable-video-xbios --disable-video-gem --disable-video-dummy \
+  --enable-video-opengl --enable-input-events --enable-pthreads \
+  --disable-video-picogui --disable-video-qtopia --enable-dlopen \
+  --enable-input-tslib --disable-video-ps3 --disable-rpath \
+"