mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-11-13 15:47:23 +00:00
Khem Raj
787d1b73e2
A full check-upgrade-status sweep of meta-oe found 121 recipes reporting UNKNOWN_BROKEN: their upstream version check resolved no version. This adds the correct check metadata to each so the version check works again. Fixes, by mechanism: - wget/tarball recipes: add UPSTREAM_CHECK_URI + UPSTREAM_CHECK_REGEX pointing at the real release listing (SourceForge files pages, GitHub releases pages, GNU/ftp mirrors, distro pools). - git recipes with release tags in a non-default format: add UPSTREAM_CHECK_GITTAGREGEX matching the actual tag scheme. - git repos with no tags at all: UPSTREAM_CHECK_COMMITS = "1". - recipes whose upstream has no checkable release channel, or whose PV format cannot be compared against upstream tags (CPAN zero-padded versions, AUTOINC "git" PVs, dash-separated tags the checker cannot convert): UPSTREAM_VERSION_UNKNOWN = "1" with an explanatory comment. Also override GITHUB_BASE_URI for libppd's sibling libcupsfilters where the github-releases class default pointed at a non-existent org (404). Only version-check metadata is touched; no SRC_URI, SRCREV, PV, or checksum is changed, so nothing that gets built is affected. Each fix was verified with devtool check-upgrade-status: 120 of 121 now resolve (MATCH, UPDATE, COMMITS, or an honestly-declared UNKNOWN). The remaining recipe (libubox) already has correct metadata and only fails locally because the git:// port to git.openwrt.org is firewalled on the build host. Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
69 lines
2.5 KiB
BlitzBasic
69 lines
2.5 KiB
BlitzBasic
SUMMARY = "Free and Open On-Chip Debugging, In-System Programming and Boundary-Scan Testing"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=599d2d1ee7fc84c0467b3d19801db870"
|
|
DEPENDS = "libusb-compat libftdi"
|
|
RDEPENDS:${PN} = "libusb1"
|
|
|
|
MIRRORS += " \
|
|
git://repo.or.cz/openocd.git git://github.com/openocd-org/openocd.git \
|
|
"
|
|
|
|
SRC_URI = " \
|
|
git://repo.or.cz/openocd.git;protocol=http;name=openocd;branch=master \
|
|
git://repo.or.cz/r/git2cl.git;protocol=http;destsuffix=tools/git2cl;name=git2cl;branch=master \
|
|
git://github.com/msteveb/jimtcl.git;protocol=https;destsuffix=${BB_GIT_DEFAULT_DESTSUFFIX}/jimtcl;name=jimtcl;branch=master \
|
|
git://repo.or.cz/r/libjaylink.git;protocol=http;destsuffix=${BB_GIT_DEFAULT_DESTSUFFIX}/src/jtag/drivers/libjaylink;name=libjaylink;branch=master \
|
|
file://0001-tcl-board-ti_-_swd_native.cfg-Add-support-for-direct.patch \
|
|
file://0002-tcl-target-ti_k3.cfg-Add-support-for-direct-memory-a.patch \
|
|
"
|
|
|
|
SRCREV_FORMAT = "openocd"
|
|
SRCREV_openocd = "66ea461846a3a4a96687c9287c3f61ae8ce0b775"
|
|
SRCREV_git2cl = "8373c9f74993e218a08819cbcdbab3f3564bbeba"
|
|
SRCREV_jimtcl = "f160866171457474f7c4d6ccda70f9b77524407e"
|
|
SRCREV_libjaylink = "0d23921a05d5d427332a142d154c213d0c306eb1"
|
|
|
|
PV = "0.12+git"
|
|
|
|
# Upstream tags releases as vX.Y.Z; PV only carries the two-component version,
|
|
# so match just the X.Y part to compare against it.
|
|
UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+\.\d+)\.\d+"
|
|
|
|
inherit pkgconfig autotools-brokensep gettext
|
|
|
|
BBCLASSEXTEND += "native nativesdk"
|
|
|
|
EXTRA_OECONF = "--enable-ftdi --enable-jtag_vpi --enable-buspirate --disable-doxygen-html --disable-werror --enable-internal-jimtcl"
|
|
|
|
do_configure() {
|
|
./bootstrap nosubmodule
|
|
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}/jimtcl/autosetup
|
|
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}/jimtcl/autosetup
|
|
oe_runconf ${EXTRA_OECONF}
|
|
}
|
|
|
|
do_install() {
|
|
oe_runmake DESTDIR=${D} install
|
|
if [ -e "${D}${infodir}" ]; then
|
|
rm -Rf ${D}${infodir}
|
|
fi
|
|
if [ -e "${D}${mandir}" ]; then
|
|
rm -Rf ${D}${mandir}
|
|
fi
|
|
if [ -e "${D}${bindir}/.debug" ]; then
|
|
rm -Rf ${D}${bindir}/.debug
|
|
fi
|
|
}
|
|
|
|
FILES:${PN} = " \
|
|
${datadir}/openocd/* \
|
|
${bindir}/openocd \
|
|
"
|
|
|
|
PACKAGECONFIG[sysfsgpio] = "--enable-sysfsgpio,--disable-sysfsgpio"
|
|
PACKAGECONFIG[remote-bitbang] = "--enable-remote-bitbang,--disable-remote-bitbang"
|
|
PACKAGECONFIG ??= "sysfsgpio remote-bitbang"
|
|
|
|
# Can't be built with ccache
|
|
CCACHE_DISABLE = "1"
|