mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-20 17:47:14 +00:00
Roy Li
03e758cd67
When ntpd starts, it will create a daemon to connect this invalid server, and fail, then ntpd will create other daemon to connect the local-only (127.127.1.0) server. The users should be aware that they need to configure the correct ntp servers, a invalid server will lead to a redundant daemon, so it is better to comment this example server to wait user to configure Signed-off-by: Roy Li <rongqing.li@windriver.com> Signed-off-by: Joe MacDonald <joe@deserted.net>
85 lines
3.4 KiB
BlitzBasic
85 lines
3.4 KiB
BlitzBasic
SUMMARY = "Very Secure FTP server"
|
|
HOMEPAGE = "https://security.appspot.com/vsftpd.html"
|
|
SECTION = "network"
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=a6067ad950b28336613aed9dd47b1271"
|
|
|
|
DEPENDS = "libcap openssl"
|
|
|
|
SRC_URI = "https://security.appspot.com/downloads/vsftpd-${PV}.tar.gz \
|
|
file://makefile-destdir.patch \
|
|
file://makefile-libs.patch \
|
|
file://makefile-strip.patch \
|
|
file://init \
|
|
file://vsftpd.conf \
|
|
file://vsftpd.user_list \
|
|
file://vsftpd.ftpusers \
|
|
file://change-secure_chroot_dir.patch \
|
|
file://volatiles.99_vsftpd \
|
|
"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=a6067ad950b28336613aed9dd47b1271 \
|
|
file://COPYRIGHT;md5=04251b2eb0f298dae376d92454f6f72e \
|
|
file://LICENSE;md5=654df2042d44b8cac8a5654fc5be63eb"
|
|
SRC_URI[md5sum] = "ad9fa952558c2c5b0426ccaccff0f972"
|
|
SRC_URI[sha256sum] = "ef70205dcd0c7f03b008b9578fb44c0cbe31e66daab8cfafb9904747c17fc2a8"
|
|
|
|
PACKAGECONFIG ??= "tcp-wrappers"
|
|
PACKAGECONFIG[tcp-wrappers] = ",,tcp-wrappers"
|
|
SRC_URI +="${@base_contains('PACKAGECONFIG', 'tcp-wrappers', 'file://vsftpd-tcp_wrappers-support.patch', '', d)}"
|
|
|
|
DEPENDS += "${@base_contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
RDEPENDS_${PN} += "${@base_contains('DISTRO_FEATURES', 'pam', 'pam-plugin-listfile', '', d)}"
|
|
PAMLIB = "${@base_contains('DISTRO_FEATURES', 'pam', '-L${STAGING_BASELIBDIR} -lpam', '', d)}"
|
|
NOPAM_SRC ="${@base_contains('PACKAGECONFIG', 'tcp-wrappers', 'file://nopam-with-tcp_wrappers.patch', 'file://nopam.patch', d)}"
|
|
SRC_URI += "${@base_contains('DISTRO_FEATURES', 'pam', '', '${NOPAM_SRC}', d)}"
|
|
|
|
inherit update-rc.d useradd
|
|
|
|
CONFFILES_${PN} = "${sysconfdir}/vsftpd.conf"
|
|
LDFLAGS_append =" -lcrypt -lcap"
|
|
|
|
do_configure() {
|
|
# Fix hardcoded /usr, /etc, /var mess.
|
|
cat tunables.c|sed s:\"/usr:\"${prefix}:g|sed s:\"/var:\"${localstatedir}:g \
|
|
|sed s:\"/etc:\"${sysconfdir}:g > tunables.c.new
|
|
mv tunables.c.new tunables.c
|
|
}
|
|
|
|
do_compile() {
|
|
oe_runmake "LIBS=-L${STAGING_LIBDIR} -lcrypt -lcap ${PAMLIB} -lwrap"
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${sbindir}
|
|
install -d ${D}${mandir}/man8
|
|
install -d ${D}${mandir}/man5
|
|
oe_runmake 'DESTDIR=${D}' install
|
|
install -d ${D}${sysconfdir}
|
|
install -m 600 ${WORKDIR}/vsftpd.conf ${D}${sysconfdir}/vsftpd.conf
|
|
install -d ${D}${sysconfdir}/init.d/
|
|
install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/vsftpd
|
|
install -d ${D}/${sysconfdir}/default/volatiles
|
|
install -m 644 ${WORKDIR}/volatiles.99_vsftpd ${D}/${sysconfdir}/default/volatiles/99_vsftpd
|
|
|
|
install -m 600 ${WORKDIR}/vsftpd.ftpusers ${D}${sysconfdir}/
|
|
install -m 600 ${WORKDIR}/vsftpd.user_list ${D}${sysconfdir}/
|
|
if ! test -z "${PAMLIB}" ; then
|
|
install -d ${D}${sysconfdir}/pam.d/
|
|
cp ${S}/RedHat/vsftpd.pam ${D}${sysconfdir}/pam.d/vsftpd
|
|
sed -i "s:/lib/security:${base_libdir}/security:" ${D}${sysconfdir}/pam.d/vsftpd
|
|
sed -i "s:ftpusers:vsftpd.ftpusers:" ${D}${sysconfdir}/pam.d/vsftpd
|
|
fi
|
|
install -d ${D}${localstatedir}/run/vsftpd/empty
|
|
}
|
|
|
|
INITSCRIPT_PACKAGES = "${PN}"
|
|
INITSCRIPT_NAME_${PN} = "vsftpd"
|
|
INITSCRIPT_PARAMS_${PN} = "defaults 80"
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM_${PN} = "--system --home-dir /var/lib/ftp --no-create-home -g ftp \
|
|
--shell /bin/false ftp "
|
|
GROUPADD_PARAM_${PN} = "-r ftp"
|
|
|