mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-15 16:07:26 +00:00
Robert Yang
1443c68987
Bashism:
possible bashism in memcached/etc/init.d/memcached line 40 (bash arrays, ${name[0|*|@]}):
if [ -r "${FILES[0]}" ]; then
possible bashism in memcached/etc/init.d/memcached line 42 (bash arrays, ${name[0|*|@]}):
for FILE in "${FILES[@]}";
possible bashism in memcached/etc/init.d/memcached line 53 (should be VAR="${VAR}foo"):
CONFIGS+=($NAME)
possible bashism in memcached/etc/init.d/memcached line 54 (should be 'b = a'):
elif [ "memcached_$2" == "$NAME" ];
possible bashism in memcached/etc/init.d/memcached line 62 (bash arrays, ${name[0|*|@]}):
if [ ${#CONFIGS[@]} == 0 ];
possible bashism in memcached/etc/init.d/memcached line 71 (bash arrays, ${name[0|*|@]}):
CONFIG_NUM=${#CONFIGS[@]}
possible bashism in memcached/etc/init.d/memcached line 72 ('((' should be '$(('):
for ((i=0; i < $CONFIG_NUM; i++)); do
possible bashism in memcached/etc/init.d/memcached line 73 (bash arrays, ${name[0|*|@]}):
NAME=${CONFIGS[${i}]}
Signed-off-by: Robert Yang <liezhi.yang@windriver.com>
54 lines
1.9 KiB
BlitzBasic
54 lines
1.9 KiB
BlitzBasic
SUMMARY = "A high-performance memory object caching system"
|
|
DESCRIPTION = "\
|
|
memcached optimizes specific high-load serving applications that are designed \
|
|
to take advantage of its versatile no-locking memory access system. Clients \
|
|
are available in several different programming languages, to suit the needs \
|
|
of the specific application. Traditionally this has been used in mod_perl \
|
|
apps to avoid storing large chunks of data in Apache memory, and to share \
|
|
this burden across several machines."
|
|
|
|
HOMEPAGE = "http://memcached.org/"
|
|
LICENSE = "BSD-3-Clause"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=7e5ded7363d335e1bb18013ca08046ff"
|
|
|
|
inherit autotools
|
|
|
|
DEPENDS += "libevent"
|
|
RDEPENDS_${PN} += "perl perl-module-posix perl-module-autoloader \
|
|
perl-module-tie-hash bash \
|
|
"
|
|
|
|
SRC_URI = "http://www.memcached.org/files/${BP}.tar.gz \
|
|
file://configure.patch \
|
|
file://memcached-add-hugetlbfs-check.patch"
|
|
|
|
# set the same COMPATIBLE_HOST as libhugetlbfs
|
|
COMPATIBLE_HOST = '(i.86|x86_64|powerpc|powerpc64|arm).*-linux'
|
|
|
|
SRC_URI[md5sum] = "46402dfbd7faadf6182283dbbd18b1a6"
|
|
SRC_URI[sha256sum] = "d9173ef6d99ba798c982ea4566cb4f0e64eb23859fdbf9926a89999d8cdc0458"
|
|
|
|
python __anonymous () {
|
|
endianness = d.getVar('SITEINFO_ENDIANNESS', True)
|
|
if endianness == 'le':
|
|
d.appendVar('EXTRA_OECONF', " ac_cv_c_endian=little")
|
|
else:
|
|
d.appendVar('EXTRA_OECONF', " ac_cv_c_endian=big")
|
|
}
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[hugetlbfs] = "--enable-hugetlbfs, --disable-hugetlbfs, libhugetlbfs"
|
|
|
|
inherit update-rc.d
|
|
|
|
INITSCRIPT_NAME = "memcached"
|
|
INITSCRIPT_PARAMS = "defaults"
|
|
|
|
do_install_append() {
|
|
install -D -m 755 ${S}/scripts/memcached-init ${D}${sysconfdir}/init.d/memcached
|
|
mkdir -p ${D}/usr/share/memcached/scripts
|
|
install -m 755 ${S}/scripts/memcached-tool ${D}/usr/share/memcached/scripts
|
|
install -m 755 ${S}/scripts/start-memcached ${D}/usr/share/memcached/scripts
|
|
}
|