mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-15 16:07:26 +00:00
Martin Jansa
4371cc095e
* libsmi is autodetected in configure, but in most cases disabled because of cross-compilation so keep it explicitly disabled * resolves following difference in builds with and without libsmi built before tcpdump: 4.7.4-r0-with/temp/log.do_configure:checking smi.h usability... yes 4.7.4-r0-with/temp/log.do_configure:checking smi.h presence... yes 4.7.4-r0-with/temp/log.do_configure:checking for smi.h... yes 4.7.4-r0-with/temp/log.do_configure:checking for smiInit in -lsmi... yes 4.7.4-r0-with/temp/log.do_configure:checking whether to enable libsmi... not when cross-compiling 4.7.4-r0-without/temp/log.do_configure:checking smi.h usability... no 4.7.4-r0-without/temp/log.do_configure:checking smi.h presence... no 4.7.4-r0-without/temp/log.do_configure:checking for smi.h... no Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com> Signed-off-by: Armin Kuster <akuster808@gmail.com>
53 lines
1.6 KiB
BlitzBasic
53 lines
1.6 KiB
BlitzBasic
SUMMARY = "A sophisticated network protocol analyzer"
|
|
HOMEPAGE = "http://www.tcpdump.org/"
|
|
LICENSE = "BSD"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=1d4b0366557951c84a94fabe3529f867"
|
|
SECTION = "console/network"
|
|
DEPENDS = "libpcap"
|
|
|
|
SRC_URI = " \
|
|
http://www.tcpdump.org/release/${BP}.tar.gz \
|
|
file://configure.patch \
|
|
file://unnecessary-to-check-libpcap.patch \
|
|
file://tcpdump-configure-dlpi.patch \
|
|
file://tcpdump-cross-getaddrinfo.patch \
|
|
file://add-ptest.patch \
|
|
file://run-ptest \
|
|
"
|
|
SRC_URI[md5sum] = "dab267ec30216a069747d10314079ec7"
|
|
SRC_URI[sha256sum] = "4c88c2a9aeb4047074f344fc9b2b6577b219972d359e192f6d12ccf983a13fd7"
|
|
export LIBS=" -lpcap"
|
|
|
|
inherit autotools-brokensep ptest
|
|
CACHED_CONFIGUREVARS = "ac_cv_linux_vers=${ac_cv_linux_vers=2}"
|
|
|
|
PACKAGECONFIG ??= "openssl ipv6"
|
|
PACKAGECONFIG[openssl] = "--with-crypto=yes, --without-openssl --without-crypto, openssl"
|
|
PACKAGECONFIG[ipv6] = "--enable-ipv6, --disable-ipv6,"
|
|
PACKAGECONFIG[smi] = "--with-smi, --without-smi,libsmi"
|
|
|
|
EXTRA_AUTORECONF += " -I m4"
|
|
|
|
do_configure_prepend() {
|
|
mkdir -p ${S}/m4
|
|
if [ -f aclocal.m4 ]; then
|
|
mv aclocal.m4 ${S}/m4
|
|
fi
|
|
# AC_CHECK_LIB(dlpi.. was looking to host /lib
|
|
sed -i 's:-L/lib::g' ./configure.in
|
|
}
|
|
do_configure_append() {
|
|
sed -i 's:-L/usr/lib::' ./Makefile
|
|
sed -i 's:-Wl,-rpath,${STAGING_LIBDIR}::' ./Makefile
|
|
sed -i 's:-I/usr/include::' ./Makefile
|
|
}
|
|
|
|
do_install_append() {
|
|
# tcpdump 4.0.0 installs a copy to /usr/sbin/tcpdump.4.0.0
|
|
rm -f ${D}${sbindir}/tcpdump.${PV}
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake buildtest-TESTS
|
|
}
|