mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-15 16:07:26 +00:00
Martin Jansa
a45830a39b
* This change is only aesthetic (unlike indentation in Python tasks). * Some recipes were using tabs. * Some were using 8 spaces. * Some were using mix or different number of spaces. * Make them consistently use 4 spaces everywhere. * Yocto styleguide advises to use tabs (but the only reason to keep tabs is the need to update a lot of recipes). Lately this advice was also merged into the styleguide on the OE wiki. * Using 4 spaces in both types of tasks is better because it's less error prone when someone is not sure if e.g. do_generate_toolchain_file() is Python or shell task and also allows to highlight every tab used in .bb, .inc, .bbappend, .bbclass as potentially bad (shouldn't be used for indenting of multiline variable assignments and cannot be used for Python tasks). * Don't indent closing quote on multiline variables we're quite inconsistent wheater it's first character on line under opening quote or under first non-whitespace character in previous line. Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com> Acked-by: Koen Kooi <koen@dominion.thruhere.net>
87 lines
3.2 KiB
BlitzBasic
87 lines
3.2 KiB
BlitzBasic
DESCRIPTION = "Opencv : The Open Computer Vision Library"
|
|
HOMEPAGE = "http://opencv.willowgarage.com/wiki/"
|
|
SECTION = "libs"
|
|
|
|
LICENSE = "BSD"
|
|
LIC_FILES_CHKSUM = "file://include/opencv2/opencv.hpp;endline=41;md5=6d690d8488a6fca7a2c192932466bb14"
|
|
|
|
ARM_INSTRUCTION_SET = "arm"
|
|
|
|
DEPENDS = "python-numpy v4l-utils libav gtk+ libtool swig swig-native python jpeg bzip2 zlib libpng tiff glib-2.0"
|
|
|
|
SRC_URI = "${SOURCEFORGE_MIRROR}/opencvlibrary/opencv-unix/${PV}/OpenCV-${PV}.tar.bz2 \
|
|
file://opencv-fix-pkgconfig-generation.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "c0a5af4ff9d0d540684c0bf00ef35dbe"
|
|
SRC_URI[sha256sum] = "f8fbe985978d4eae73e8c3b526ed40a37d4761d2029a5b035233f58146f6f59b"
|
|
|
|
PR = "r2"
|
|
|
|
S = "${WORKDIR}/OpenCV-${PV}"
|
|
|
|
# Do an out-of-tree build
|
|
OECMAKE_SOURCEPATH = "${S}"
|
|
OECMAKE_BUILDPATH = "${WORKDIR}/build-${TARGET_ARCH}"
|
|
|
|
EXTRA_OECMAKE = "-DPYTHON_NUMPY_INCLUDE_DIR:PATH=${STAGING_LIBDIR}/${PYTHON_DIR}/site-packages/numpy/core/include \
|
|
-DBUILD_PYTHON_SUPPORT=ON \
|
|
-DWITH_FFMPEG=ON \
|
|
-DWITH_GSTREAMER=OFF \
|
|
-DWITH_V4L=ON \
|
|
-DWITH_GTK=ON \
|
|
-DCMAKE_SKIP_RPATH=ON \
|
|
${@bb.utils.contains("TARGET_CC_ARCH", "-msse3", "-DENABLE_SSE=1 -DENABLE_SSE2=1 -DENABLE_SSE3=1 -DENABLE_SSSE3=1", "", d)} \
|
|
"
|
|
|
|
inherit distutils-base pkgconfig cmake
|
|
|
|
export BUILD_SYS
|
|
export HOST_SYS
|
|
export PYTHON_CSPEC="-I${STAGING_INCDIR}/${PYTHON_DIR}"
|
|
export PYTHON="${STAGING_BINDIR_NATIVE}/python"
|
|
|
|
TARGET_CC_ARCH += "-I${S}/include "
|
|
|
|
PACKAGES += "${PN}-apps python-opencv"
|
|
|
|
python populate_packages_prepend () {
|
|
cv_libdir = d.expand('${libdir}')
|
|
cv_libdir_dbg = d.expand('${libdir}/.debug')
|
|
do_split_packages(d, cv_libdir, '^lib(.*)\.so$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev', allow_links=True)
|
|
do_split_packages(d, cv_libdir, '^lib(.*)\.la$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev')
|
|
do_split_packages(d, cv_libdir, '^lib(.*)\.a$', 'lib%s-dev', 'OpenCV %s development package', extra_depends='${PN}-dev')
|
|
do_split_packages(d, cv_libdir, '^lib(.*)\.so\.*', 'lib%s', 'OpenCV %s library', extra_depends='', allow_links=True)
|
|
|
|
pn = d.getVar('PN', 1)
|
|
metapkg = pn + '-dev'
|
|
d.setVar('ALLOW_EMPTY_' + metapkg, "1")
|
|
blacklist = [ metapkg ]
|
|
metapkg_rdepends = [ ]
|
|
packages = d.getVar('PACKAGES', 1).split()
|
|
for pkg in packages[1:]:
|
|
if not pkg in blacklist and not pkg in metapkg_rdepends and pkg.endswith('-dev'):
|
|
metapkg_rdepends.append(pkg)
|
|
d.setVar('RRECOMMENDS_' + metapkg, ' '.join(metapkg_rdepends))
|
|
}
|
|
|
|
PACKAGES_DYNAMIC += "^libopencv-.*"
|
|
|
|
FILES_${PN} = ""
|
|
FILES_${PN}-apps = "${bindir}/* ${datadir}/OpenCV"
|
|
FILES_${PN}-dbg += "${libdir}/.debug"
|
|
FILES_${PN}-dev = "${includedir} ${libdir}/pkgconfig"
|
|
FILES_${PN}-doc = "${datadir}/OpenCV/doc"
|
|
|
|
ALLOW_EMPTY_${PN} = "1"
|
|
|
|
INSANE_SKIP_python-opencv = "True"
|
|
DESCRIPTION_python-opencv = "Python bindings to opencv"
|
|
FILES_python-opencv = "${PYTHON_SITEPACKAGES_DIR}/*"
|
|
RDEPENDS_python-opencv = "python-core python-numpy"
|
|
|
|
do_install_append() {
|
|
cp ${S}/include/opencv/*.h ${D}${includedir}/opencv/
|
|
sed -i '/blobtrack/d' ${D}${includedir}/opencv/cvaux.h
|
|
}
|