mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 17:59:59 +00:00
Martin Jansa
a45830a39b
* This change is only aesthetic (unlike indentation in Python tasks). * Some recipes were using tabs. * Some were using 8 spaces. * Some were using mix or different number of spaces. * Make them consistently use 4 spaces everywhere. * Yocto styleguide advises to use tabs (but the only reason to keep tabs is the need to update a lot of recipes). Lately this advice was also merged into the styleguide on the OE wiki. * Using 4 spaces in both types of tasks is better because it's less error prone when someone is not sure if e.g. do_generate_toolchain_file() is Python or shell task and also allows to highlight every tab used in .bb, .inc, .bbappend, .bbclass as potentially bad (shouldn't be used for indenting of multiline variable assignments and cannot be used for Python tasks). * Don't indent closing quote on multiline variables we're quite inconsistent wheater it's first character on line under opening quote or under first non-whitespace character in previous line. Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com> Acked-by: Koen Kooi <koen@dominion.thruhere.net>
96 lines
3.1 KiB
BlitzBasic
96 lines
3.1 KiB
BlitzBasic
DESCRIPTION = "NetworkManager"
|
|
SECTION = "net/misc"
|
|
|
|
LICENSE = "GPLv2+"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=cbbffd568227ada506640fe950a4823b"
|
|
|
|
PR = "r11"
|
|
|
|
DEPENDS = "libnl dbus dbus-glib udev wireless-tools polkit gnutls util-linux ppp"
|
|
DEPENDS += "${@base_contains('DISTRO_FEATURES', 'systemd', 'systemd', '', d)}"
|
|
|
|
inherit gnome gettext systemd
|
|
|
|
SRC_URI = "${GNOME_MIRROR}/NetworkManager/${@gnome_verdir("${PV}")}/NetworkManager-${PV}.tar.bz2 \
|
|
file://0001-don-t-try-to-run-sbin-dhclient-to-get-the-version-nu.patch \
|
|
file://0002-ppp-don-t-use-struct-ifpppstatsreq-that-was-removed-.patch \
|
|
file://gtk-doc.make \
|
|
"
|
|
SRC_URI[md5sum] = "bc0b00b8a187762d93c50a9706b4c5c3"
|
|
SRC_URI[sha256sum] = "a178ed2f0b5a1045ec47b217ea531d0feba9208f6bcfe64b701174a5c1479816"
|
|
|
|
|
|
S = "${WORKDIR}/NetworkManager-${PV}"
|
|
|
|
EXTRA_OECONF = " \
|
|
--with-distro=debian \
|
|
--with-crypto=gnutls \
|
|
--disable-more-warnings \
|
|
--with-dhclient=${base_sbindir}/dhclient \
|
|
--with-iptables=${sbindir}/iptables \
|
|
--with-tests \
|
|
"
|
|
|
|
EXTRA_OECONF += "${@base_contains('DISTRO_FEATURES', 'systemd', '--with-systemdsystemunitdir=${systemd_unitdir}/system/', '--without-systemdsystemunitdir', d)}"
|
|
|
|
do_configure_prepend() {
|
|
cp ${WORKDIR}/gtk-doc.make ${S}/
|
|
echo "EXTRA_DIST = version.xml" > gnome-doc-utils.make
|
|
sed -i -e 's:man \\:man:' -e s:docs::g ${S}/Makefile.am
|
|
sed -i -e /^docs/d ${S}/configure.ac
|
|
}
|
|
|
|
# Work around dbus permission problems since we lack a proper at_console
|
|
do_install_prepend() {
|
|
sed -i -e s:deny:allow:g ${S}/src/NetworkManager.conf
|
|
sed -i -e s:deny:allow:g ${S}/callouts/nm-dispatcher.conf
|
|
}
|
|
|
|
do_install_append () {
|
|
install -d ${D}/etc/dbus-1/event.d
|
|
# Additional test binaries
|
|
install -d ${D}/usr/bin
|
|
install -m 0755 ${S}/test/.libs/libnm* ${D}/usr/bin
|
|
|
|
install -d ${D}/etc/NetworkManager/
|
|
|
|
# Install an empty VPN folder as nm-connection-editor will happily segfault without it :o.
|
|
# With or without VPN support built in ;).
|
|
install -d ${D}/etc/NetworkManager/VPN
|
|
}
|
|
|
|
PACKAGES =+ "libnmutil libnmglib libnmglib-vpn ${PN}-tests"
|
|
|
|
FILES_libnmutil += "${libdir}/libnm-util.so.*"
|
|
FILES_libnmglib += "${libdir}/libnm_glib.so.*"
|
|
FILES_libnmglib-vpn += "${libdir}/libnm_glib_vpn.so.*"
|
|
|
|
FILES_${PN} += " \
|
|
${libexecdir} \
|
|
${libdir}/pppd/*/nm-pppd-plugin.so \
|
|
${libdir}/NetworkManager/*.so \
|
|
${datadir}/polkit-1 \
|
|
${datadir}/dbus-1 \
|
|
${base_libdir}/udev/* \
|
|
${systemd_unitdir}/system/NetworkManager-wait-online.service \
|
|
"
|
|
|
|
RRECOMMENDS_${PN} += "iptables"
|
|
RCONFLICTS_${PN} = "connman"
|
|
RDEPENDS_${PN} = "wpa-supplicant dhcp-client \
|
|
${@base_contains('COMBINED_FEATURES', '3gmodem', 'ppp', '', d)} \
|
|
"
|
|
|
|
FILES_${PN}-dbg += "${libdir}/NetworkManager/.debug/ \
|
|
${libdir}/pppd/*/.debug/ "
|
|
|
|
FILES_${PN}-dev += "${datadir}/NetworkManager/gdb-cmd \
|
|
${libdir}/pppd/*/*.la \
|
|
${libdir}/NetworkManager/*.la"
|
|
|
|
FILES_${PN}-tests = "${bindir}/nm-tool \
|
|
${bindir}/libnm_glib_test \
|
|
${bindir}/nm-online"
|
|
|
|
SYSTEMD_SERVICE_${PN} = "NetworkManager.service"
|