mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-15 16:07:26 +00:00
Khem Raj
f3b1dd6a45
Latest musl shows build failures e.g. ../git/src/profile-handler.cc:275:8: error: no member named '_sigev_un' in 'sigevent' sevp._sigev_un._tid = sys_gettid(); ~~~~ ^ Signed-off-by: Khem Raj <raj.khem@gmail.com>
51 lines
2.0 KiB
BlitzBasic
51 lines
2.0 KiB
BlitzBasic
SUMMARY = "Fast, multi-threaded malloc() and nifty performance analysis tools"
|
|
HOMEPAGE = "https://github.com/gperftools/gperftools"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=762732742c73dc6c7fbe8632f06c059a"
|
|
|
|
SRCREV = "180bfa10d7cb38e8b3784d60943d50e8fcef0dcb"
|
|
SRC_URI = "git://github.com/gperftools/gperftools \
|
|
file://0001-Support-Atomic-ops-on-clang.patch \
|
|
file://0001-fix-build-with-musl-libc.patch \
|
|
file://0001-disbale-heap-checkers-and-debug-allocator-on-musl.patch \
|
|
file://disable_libunwind_aarch64.patch \
|
|
file://sgidef.patch \
|
|
file://0001-profile-handler-Specify-libc-specific-thread_id.patch \
|
|
"
|
|
|
|
inherit autotools
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
# On mips, we have the following error.
|
|
# do_page_fault(): sending SIGSEGV to ls for invalid read access from 00000008
|
|
# Segmentation fault (core dumped)
|
|
COMPATIBLE_HOST_mipsarch = "null"
|
|
COMPATIBLE_HOST_riscv64 = "null"
|
|
COMPATIBLE_HOST_riscv32 = "null"
|
|
|
|
# Disable thumb1
|
|
# {standard input}: Assembler messages:
|
|
# {standard input}:434: Error: lo register required -- `ldr pc,[sp]'
|
|
# Makefile:4538: recipe for target 'src/base/libtcmalloc_la-linuxthreads.lo' failed
|
|
ARM_INSTRUCTION_SET_armv5 = "arm"
|
|
ARM_INSTRUCTION_SET_toolchain-clang_arm = "arm"
|
|
|
|
PACKAGECONFIG ?= "libunwind static"
|
|
PACKAGECONFIG_remove_arm_libc-musl = "libunwind"
|
|
PACKAGECONFIG_remove_riscv64 = "libunwind"
|
|
PACKAGECONFIG_remove_riscv32 = "libunwind"
|
|
|
|
PACKAGECONFIG[libunwind] = "--enable-libunwind,--disable-libunwind,libunwind"
|
|
PACKAGECONFIG[static] = "--enable-static,--disable-static,"
|
|
|
|
PACKAGE_BEFORE_PN += "libtcmalloc-minimal"
|
|
FILES_libtcmalloc-minimal = "${libdir}/libtcmalloc_minimal*${SOLIBS} ${libdir}/libtcmalloc_minimal_debug*${SOLIBS}"
|
|
|
|
# pprof tool requires Getopt::long and POSIX perl5 modules.
|
|
# Also runs `objdump` on each cpuprofile data file
|
|
RDEPENDS_${PN} += "binutils perl-module-getopt-long perl-module-posix"
|
|
|
|
RDEPENDS_${PN} += "libtcmalloc-minimal (= ${EXTENDPKGV})"
|
|
|