mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-17 04:37:19 +00:00
Yi Fan Yu
138e4f59c3
Removed patches:
* avoid-absolute-path-when-searching-for-libdlpi.patch
reason: this is a solaris specific patch,
It no longer generates QA error.
* unnecessary-to-check-libpcap.patch
reason: upstream changed the logic, a new patch was needed.
New patch:
* 0001-aclocal.m4-Skip-checking-for-pcap-config.patch
reason: configure shouldn't look for pcap-config.
upstream reference: cfc4c750a
Modified patch:
* add-ptest.patch
reason: Makefile had slight change.
new unrelated perl script was introduced,
removed to make package QA happy.
License:
upstream removed some whitespace
Ptest:
binaries are now present in /usr/bin not /usr/sbin
upstream commit: 95096be4f
add perl libraries dependencies
tests passed: 571 (qemux86-64)
tests failed: 0
Signed-off-by: Yi Fan Yu <yifan.yu@windriver.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
62 lines
1.6 KiB
BlitzBasic
62 lines
1.6 KiB
BlitzBasic
SUMMARY = "A sophisticated network protocol analyzer"
|
|
HOMEPAGE = "http://www.tcpdump.org/"
|
|
SECTION = "net"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=5eb289217c160e2920d2e35bddc36453"
|
|
|
|
DEPENDS = "libpcap"
|
|
|
|
RDEPENDS_${PN}-ptest += " make perl \
|
|
perl-module-file-basename \
|
|
perl-module-file-spec \
|
|
perl-module-file-spec-unix \
|
|
perl-module-file-path \
|
|
perl-module-file-glob \
|
|
perl-module-data-dumper \
|
|
perl-module-bytes \
|
|
perl-module-posix \
|
|
perl-module-carp \
|
|
perl-module-cwd \
|
|
perl-module-constant \
|
|
"
|
|
|
|
SRC_URI = " \
|
|
http://www.tcpdump.org/release/${BP}.tar.gz \
|
|
file://add-ptest.patch \
|
|
file://run-ptest \
|
|
file://0001-aclocal.m4-Skip-checking-for-pcap-config.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "b10aa2f497def7283bc060f626879ce5"
|
|
SRC_URI[sha256sum] = "8cf2f17a9528774a7b41060323be8b73f76024f7778f59c34efa65d49d80b842"
|
|
|
|
UPSTREAM_CHECK_REGEX = "tcpdump-(?P<pver>\d+(\.(?!99)\d+)+)\.tar"
|
|
|
|
inherit autotools-brokensep ptest
|
|
|
|
PACKAGECONFIG ?= "openssl"
|
|
|
|
PACKAGECONFIG[libcap-ng] = "--with-cap-ng,--without-cap-ng,libcap-ng"
|
|
PACKAGECONFIG[openssl] = "--with-crypto,--without-crypto,openssl"
|
|
PACKAGECONFIG[smi] = "--with-smi,--without-smi,libsmi"
|
|
# Note: CVE-2018-10103 (SMB - partially fixed, but SMB printing disabled)
|
|
PACKAGECONFIG[smb] = "--enable-smb,--disable-smb"
|
|
|
|
EXTRA_AUTORECONF += "-I m4"
|
|
|
|
do_configure_prepend() {
|
|
mkdir -p ${S}/m4
|
|
if [ -f aclocal.m4 ]; then
|
|
mv aclocal.m4 ${S}/m4
|
|
fi
|
|
}
|
|
|
|
do_install_append() {
|
|
# make install installs an unneeded extra copy of the tcpdump binary
|
|
rm ${D}${bindir}/tcpdump.${PV}
|
|
}
|
|
|
|
do_compile_ptest() {
|
|
oe_runmake buildtest-TESTS
|
|
}
|