mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-27 20:07:25 +00:00
Martin Jansa
c61dc077bb
This is the result of automated script (0.9.1) conversion: oe-core/scripts/contrib/convert-overrides.py . converting the metadata to use ":" as the override character instead of "_". Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
53 lines
1.9 KiB
BlitzBasic
53 lines
1.9 KiB
BlitzBasic
SUMMARY = "A high-performance memory object caching system"
|
|
DESCRIPTION = "\
|
|
memcached optimizes specific high-load serving applications that are designed \
|
|
to take advantage of its versatile no-locking memory access system. Clients \
|
|
are available in several different programming languages, to suit the needs \
|
|
of the specific application. Traditionally this has been used in mod_perl \
|
|
apps to avoid storing large chunks of data in Apache memory, and to share \
|
|
this burden across several machines."
|
|
SECTION = "web"
|
|
HOMEPAGE = "http://memcached.org/"
|
|
LICENSE = "BSD-3-Clause"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=7e5ded7363d335e1bb18013ca08046ff"
|
|
|
|
inherit autotools
|
|
|
|
DEPENDS += "libevent"
|
|
RDEPENDS:${PN} += "perl perl-module-posix perl-module-autoloader \
|
|
perl-module-tie-hash bash \
|
|
"
|
|
|
|
SRC_URI = "http://www.memcached.org/files/${BP}.tar.gz \
|
|
file://memcached-add-hugetlbfs-check.patch \
|
|
file://0002-stats_prefix.c-Check-for-NDEBUG-before-using-total_w.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "d5a62ce377314dbffdb37c4467e7763e3abae376a16171e613cbe69956f092d1"
|
|
|
|
# set the same COMPATIBLE_HOST as libhugetlbfs
|
|
COMPATIBLE_HOST = "(i.86|x86_64|powerpc|powerpc64|aarch64|arm).*-linux*"
|
|
|
|
python __anonymous () {
|
|
endianness = d.getVar('SITEINFO_ENDIANNESS')
|
|
if endianness == 'le':
|
|
d.appendVar('EXTRA_OECONF', " ac_cv_c_endian=little")
|
|
else:
|
|
d.appendVar('EXTRA_OECONF', " ac_cv_c_endian=big")
|
|
}
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[hugetlbfs] = "--enable-hugetlbfs, --disable-hugetlbfs, libhugetlbfs"
|
|
|
|
inherit update-rc.d
|
|
|
|
INITSCRIPT_NAME = "memcached"
|
|
INITSCRIPT_PARAMS = "defaults"
|
|
|
|
do_install:append() {
|
|
install -D -m 755 ${S}/scripts/memcached-init ${D}${sysconfdir}/init.d/memcached
|
|
mkdir -p ${D}/usr/share/memcached/scripts
|
|
install -m 755 ${S}/scripts/memcached-tool ${D}/usr/share/memcached/scripts
|
|
install -m 755 ${S}/scripts/start-memcached ${D}/usr/share/memcached/scripts
|
|
}
|