mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-14 05:49:57 +00:00
Armin Kuster
1659d38199
This patch updates SRC_URIs using git to include branch=master if no branch is set and also to use protocol=https for github urls as generated by the conversion script in OE-Core. I tried backporting Richard's master change but there where many merge conflicts. I went the lazy route and ran the script. This is work based on "b402a3076 recipes: Update SRC_URI branch and protocols" Signed-off-by: Armin Kuster <akuster808@gmail.com>
44 lines
1.1 KiB
BlitzBasic
44 lines
1.1 KiB
BlitzBasic
SUMMARY = "Memory Efficient Serialization Library"
|
|
HOMEPAGE = "https://github.com/google/flatbuffers"
|
|
SECTION = "console/tools"
|
|
LICENSE = "Apache-2.0"
|
|
|
|
inherit python3-dir
|
|
|
|
PACKAGE_BEFORE_PN = "${PN}-compiler ${PN}-${PYTHON_PN}"
|
|
|
|
RDEPENDS:${PN}-compiler = "${PN}"
|
|
RDEPENDS:${PN}-${PYTHON_PN} = "${PN}"
|
|
RDEPENDS:${PN}-dev += "${PN}-compiler"
|
|
|
|
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=3b83ef96387f14655fc854ddc3c6bd57"
|
|
|
|
SRCREV = "a9a295fecf3fbd5a4f571f53b01f63202a3e2113"
|
|
SRC_URI = "git://github.com/google/flatbuffers.git;branch=master;protocol=https"
|
|
S = "${WORKDIR}/git"
|
|
|
|
CVE_CHECK_WHITELIST += "CVE-2020-35864"
|
|
|
|
CXXFLAGS += "-fPIC"
|
|
BUILD_CXXFLAGS += "-fPIC"
|
|
|
|
# BUILD_TYPE=Release is required, otherwise flatc is not installed
|
|
EXTRA_OECMAKE += "\
|
|
-DCMAKE_BUILD_TYPE=Release \
|
|
-DFLATBUFFERS_BUILD_TESTS=OFF \
|
|
-DFLATBUFFERS_BUILD_SHAREDLIB=ON \
|
|
"
|
|
|
|
inherit cmake
|
|
|
|
do_install:append() {
|
|
install -d ${D}${PYTHON_SITEPACKAGES_DIR}
|
|
cp -rf ${S}/python/flatbuffers ${D}${PYTHON_SITEPACKAGES_DIR}
|
|
}
|
|
|
|
FILES:${PN}-compiler = "${bindir}"
|
|
|
|
FILES:${PN}-${PYTHON_PN} = "${PYTHON_SITEPACKAGES_DIR}"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|