mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-16 16:27:27 +00:00
Roy Li
8d2d193ce3
configure the systemd unit file dir, otherwise it will be auto-checked
by 'pkg-config --variable=systemdsystemunitdir systemd', but if systemd
is not built firstly, and the the unit file will not be installed, and
lead to below error:
ERROR: Function failed: SYSTEMD_SERVICE_lldpd value lldpd.service does not exist
and disable sysusersdir, since sysuser is not used currently.
Signed-off-by: Roy Li <rongqing.li@windriver.com>
Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
Signed-off-by: Joe MacDonald <joe_macdonald@mentor.com>
Signed-off-by: Armin Kuster <akuster808@gmail.com>
72 lines
2.7 KiB
BlitzBasic
72 lines
2.7 KiB
BlitzBasic
SUMMARY = "A 802.1ab implementation (LLDP) to help you locate neighbors of all your equipments"
|
|
SECTION = "net/misc"
|
|
LICENSE = "ISC"
|
|
LIC_FILES_CHKSUM = "file://${COREBASE}/meta/files/common-licenses/ISC;md5=f3b90e78ea0cffb20bf5cca7947a896d"
|
|
|
|
DEPENDS = "libbsd libevent"
|
|
|
|
SRC_URI = "\
|
|
http://media.luffy.cx/files/${PN}/${PN}-${PV}.tar.gz \
|
|
file://lldpd.init.d \
|
|
file://lldpd.default \
|
|
file://fix-libevent-configure.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "8cb74065956bc32a575ee5203b0e0fb5"
|
|
SRC_URI[sha256sum] = "6b50b8aa47d1424a93ba3df55af26da41f7d5718db8d25e99291c4a6cd09c20e"
|
|
|
|
inherit autotools update-rc.d useradd systemd pkgconfig
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM_${PN} = "--system -g lldpd --shell /bin/false lldpd"
|
|
GROUPADD_PARAM_${PN} = "--system lldpd"
|
|
|
|
EXTRA_OECONF += "--without-embedded-libevent \
|
|
--disable-oldies \
|
|
--with-privsep-user=lldpd \
|
|
--with-privsep-group=lldpd \
|
|
--with-systemdsystemunitdir=${systemd_system_unitdir} \
|
|
--without-sysusersdir \
|
|
"
|
|
|
|
PACKAGECONFIG ??= "cdp fdp edp sonmp lldpmed dot1 dot3"
|
|
PACKAGECONFIG[json] = "--with-json,--without-json,jansson"
|
|
PACKAGECONFIG[xml] = "--with-xml,--without-xml,libxm2"
|
|
PACKAGECONFIG[snmp] = "--with-snmp,--without-snmp,net-snmp"
|
|
PACKAGECONFIG[readline] = "--with-readline,--without-readline,readline"
|
|
PACKAGECONFIG[seccomp] = "--with-seccomp,--without-seccomp,libseccomp"
|
|
PACKAGECONFIG[cdp] = "--enable-cdp,--disable-cdp"
|
|
PACKAGECONFIG[fdp] = "--enable-fdp,--disable-fdp"
|
|
PACKAGECONFIG[edp] = "--enable-edp,--disable-edp"
|
|
PACKAGECONFIG[sonmp] = "--enable-sonmp,--disable-sonmp"
|
|
PACKAGECONFIG[lldpmed] = "--enable-lldpmed,--disable-lldpmed"
|
|
PACKAGECONFIG[dot1] = "--enable-dot1,--disable-dot1"
|
|
PACKAGECONFIG[dot3] = "--enable-dot3,--disable-dot3"
|
|
PACKAGECONFIG[custom] = "--enable-custom,--disable-custom"
|
|
|
|
INITSCRIPT_NAME = "lldpd"
|
|
INITSCRIPT_PARAMS = "defaults"
|
|
|
|
SYSTEMD_SERVICE_${PN} = "lldpd.service"
|
|
|
|
do_install_append() {
|
|
install -Dm 0755 ${WORKDIR}/lldpd.init.d ${D}${sysconfdir}/init.d/lldpd
|
|
install -Dm 0644 ${WORKDIR}/lldpd.default ${D}${sysconfdir}/default/lldpd
|
|
# Make an empty configuration file
|
|
touch ${D}${sysconfdir}/lldpd.conf
|
|
}
|
|
|
|
PACKAGES =+ "${PN}-bash-completion ${PN}-zsh-completion"
|
|
|
|
FILES_${PN} += "${libdir}/sysusers.d"
|
|
RDEPENDS_${PN} += "os-release"
|
|
|
|
FILES_${PN}-bash-completion += "${sysconfdir}/bash_completion.d/ \
|
|
${datadir}/bash-completion/ \
|
|
"
|
|
RDEPENDS_${PN}-bash-completion += "bash"
|
|
|
|
FILES_${PN}-zsh-completion += "${datadir}/zsh/"
|
|
# FIXME: zsh is broken in meta-oe so this cannot be enabled for now
|
|
#RDEPENDS_${PN}-zsh-completion += "zsh"
|