mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-15 18:20:10 +00:00
Martin Jansa
7bc138a365
* cifs.idmap links with keyutils as log.do_package shows: DEBUG: cifs-utils: Dependency libkeyutils.so.1 requires package keyutils (used by files: /home2/mjansa/build/build-starfish-jethro/BUILD/work/h15-starfish-linux-gnueabi/cifs-utils/6.4-r0/packages-split/cifs-utils/usr/sbin/cifs.idmap) * that causes following QA issue when keyutils are autodetected from sysroot: WARNING: QA Issue: cifs-utils rdepends on keyutils, but it isn't a build dependency? [build-deps] Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
35 lines
1.4 KiB
BlitzBasic
35 lines
1.4 KiB
BlitzBasic
DESCRIPTION = "A a package of utilities for doing and managing mounts of the Linux CIFS filesystem."
|
|
HOMEPAGE = "http://wiki.samba.org/index.php/LinuxCIFS_utils"
|
|
SECTION = "otherosfs"
|
|
LICENSE = "GPLv3 & LGPLv3"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=d32239bcb673463ab874e80d47fae504"
|
|
|
|
DEPENDS = "samba"
|
|
PV = "6.4"
|
|
|
|
SRCREV = "487f46da737291877867cbd3acb40fea087d3863"
|
|
SRC_URI = "git://git.samba.org/cifs-utils.git"
|
|
|
|
S = "${WORKDIR}/git"
|
|
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[cap] = "--with-libcap,--without-libcap,libcap"
|
|
# when enabled, it creates ${bindir}/cifscreds and --ignore-fail-on-non-empty in do_install_append is needed
|
|
PACKAGECONFIG[cifscreds] = "--enable-cifscreds,--disable-cifscreds,keyutils"
|
|
# when enabled, it creates ${sbindir}/cifs.upcall and --ignore-fail-on-non-empty in do_install_append is needed
|
|
PACKAGECONFIG[cifsupcall] = "--enable-cifsupcall,--disable-cifsupcall,krb5 talloc keyutils"
|
|
PACKAGECONFIG[cifsidmap] = "--enable-cifsidmap,--disable-cifsidmap, keyutils"
|
|
PACKAGECONFIG[pam] = "--enable-pam --with-pamdir=${base_libdir}/security,--disable-pam,libpam keyutils"
|
|
|
|
inherit autotools pkgconfig
|
|
|
|
do_install_append() {
|
|
# Remove empty /usr/bin and /usr/sbin directories since the mount helper
|
|
# is installed to /sbin
|
|
rmdir --ignore-fail-on-non-empty ${D}${bindir} ${D}${sbindir}
|
|
}
|
|
|
|
FILES_${PN} += "${base_libdir}/security"
|
|
FILES_${PN}-dbg += "${base_libdir}/security/.debug"
|
|
RRECOMMENDS_${PN} = "kernel-module-cifs"
|