mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-15 16:07:26 +00:00
Otavio Salvador
a73d46176d
The 2.4 version is the only version available so makes no sense to set it as lower preference. Signed-off-by: Otavio Salvador <otavio@ossystems.com.br> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com>
47 lines
1.4 KiB
BlitzBasic
47 lines
1.4 KiB
BlitzBasic
HOMEPAGE = "http://hostap.epitest.fi"
|
|
SECTION = "kernel/userland"
|
|
LICENSE = "GPLv2 | BSD"
|
|
LIC_FILES_CHKSUM = "file://README;md5=4d53178f44d4b38418a4fa8de365e11c"
|
|
DEPENDS = "libnl openssl"
|
|
SUMMARY = "User space daemon for extended IEEE 802.11 management"
|
|
|
|
inherit update-rc.d systemd
|
|
INITSCRIPT_NAME = "hostapd"
|
|
|
|
SYSTEMD_SERVICE_${PN} = "hostapd.service"
|
|
SYSTEMD_AUTO_ENABLE_${PN} = "disable"
|
|
|
|
SRC_URI = " \
|
|
http://hostap.epitest.fi/releases/hostapd-${PV}.tar.gz \
|
|
file://defconfig \
|
|
file://init \
|
|
file://hostapd.service \
|
|
"
|
|
|
|
S = "${WORKDIR}/hostapd-${PV}/hostapd"
|
|
|
|
|
|
do_configure() {
|
|
install -m 0644 ${WORKDIR}/defconfig ${S}/.config
|
|
}
|
|
|
|
do_compile() {
|
|
export CFLAGS="-MMD -O2 -Wall -g -I${STAGING_INCDIR}/libnl3"
|
|
make
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}${sbindir} ${D}${sysconfdir}/init.d ${D}${systemd_unitdir}/system/
|
|
install -m 0644 ${S}/hostapd.conf ${D}${sysconfdir}
|
|
install -m 0755 ${S}/hostapd ${D}${sbindir}
|
|
install -m 0755 ${S}/hostapd_cli ${D}${sbindir}
|
|
install -m 755 ${WORKDIR}/init ${D}${sysconfdir}/init.d/hostapd
|
|
install -m 0644 ${WORKDIR}/hostapd.service ${D}${systemd_unitdir}/system/
|
|
sed -i -e 's,@SBINDIR@,${sbindir},g' -e 's,@SYSCONFDIR@,${sysconfdir},g' ${D}${systemd_unitdir}/system/hostapd.service
|
|
}
|
|
|
|
CONFFILES_${PN} += "${sysconfdir}/hostapd.conf"
|
|
|
|
SRC_URI[md5sum] = "04578f3f2c3eb1bec1adf30473813912"
|
|
SRC_URI[sha256sum] = "6fe0eb6bd1c9cbd24952ece8586b6f7bd14ab358edfda99794e79b9b9dbd657f"
|