mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-17 04:37:19 +00:00
Gyorgy Sarvari
bd76c44c9e
These releases contain many bugfixes. Changelog: 42.9 ==== * Do not overwrite previously set offsets on attach * Don't disable KMS modifiers on newer i915 systems * Reduce memory bandwidth usage in some GPUs * Fix pointer constrains with subsurfaces * Fix partial updates on offscreen rotated screens * Do not require a physical device to update pointer visibility * Fix Xwayland focus regressions 42.8 ==== * Skip resize effects for tiled windows during user grabs * Disable direct scanout during drag-n-drop operations * Ignore unmapped subsurfaces in direct scanout check * Fix cursor disappearing over windows during grabs * Fix cursor position in window screencasts * Fix initialization of keyboard accessibility * Don't allow window activation to break global grabs * Fixed crashes * Plugged leak * Misc. bug fixes and cleanups 42.7 ==== * Always send modifiers to clients if supported * Make NVIDIA + gbm use atomic mode setting * Disable client modifiers with amdgpu driver * Handle stage view updates without allocation more gracefully * Fix window screenshots being cut off at the bottom right * Implement wl_output v3 and v4 * Fix recalculating viewport after window resize * Fixed crashes * Misc. bug fixes and cleanups 42.6 ==== * Add quirk to work around issue with Mali GPUs * Stop sending frame callbacks to minimized clients * Fixed crashes * Misc. bug fixes and cleanups 42.5 ==== * Improve heuristics for adding fallback monitor modes * Fixed crash * Misc. bug fixes and cleanups 42.4 ==== * screencast: Set correct stride when using dmabufs * Fix glitches in apps using subsurfaces * Reduce client work when entering overview * Highlight actors becoming reactive under the pointer * Fall back to ARGB if XRGB is not supported * Support direct scanout on GPUs without modifiers support * Fix registering as X11 window manager if GDK_BACKEND is set * Fixed crash * Plugged leak * Misc. bug fixes and cleanups 42.3 ==== * wayland: Fix rotation transform * Fix dma-buf screencast regression * Fix monitor mirroring in some cases * Fixed crash * Plugged leak 42.2 ==== * Don't use direct scanout for transparent windows * Fix initialization of privacy mode in displays that support it * Fix --replace again * Improve picking a window for direct scanout * Do not allow windows to steal focus when the shell has a grab * Fix night light without GAMMA_LUT property * Fixed crash * Misc. bug fixes 42.1 ==== * Send correct LEAVE events when entering windows * Be more forgiving with wrongly sized clients * Add ClutterInputCapabilities enum and device property * Fall back if COPY_MODE_SECONDARY_GPU fails to init * Fix missing root window properties after XWayland start * wayland/shm: Add support for ABGR8888 and XBGR8888 formats * Keep actors dirty if a redraw was queued up during paint() * Fix overview painting of shaped texture with layer snippets * Survive missing GAMMA_LUT KMS property * Record current event when going through event filters * Pass events to pointer a11y before going through filters * Update cursor when scaled or transformed * Fix screen cast when DMA buffer fails or can't be used * Repick when pointer actor goes unmapped * Improve IM support * Allow using dumb buffers for cursor sprites * wayland/dma-buf: Only advertise supported formats * Fix screen cast cursor metadata with unthrottled input * Fixed crashes * Plugged memory leak * Misc. bug fixes and cleanups Signed-off-by: Gyorgy Sarvari <skandigraun@gmail.com>
99 lines
3.0 KiB
BlitzBasic
99 lines
3.0 KiB
BlitzBasic
SUMMARY = "Window and compositing manager based on Clutter"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
DEPENDS = " \
|
|
xserver-xorg-cvt-native \
|
|
wayland-native \
|
|
virtual/libx11 \
|
|
graphene \
|
|
gtk+3 \
|
|
gdk-pixbuf \
|
|
cairo \
|
|
pango \
|
|
gsettings-desktop-schemas \
|
|
json-glib \
|
|
gnome-desktop \
|
|
gnome-settings-daemon \
|
|
libxtst \
|
|
libxkbfile \
|
|
xinerama \
|
|
xwayland \
|
|
"
|
|
|
|
GNOMEBASEBUILDCLASS = "meson"
|
|
|
|
inherit gnomebase gsettings gobject-introspection gettext features_check
|
|
|
|
SRC_URI[archive.sha256sum] = "d080e52f2c47fbfdf03248b11354d039b4aa453f1997288b30af841d6dcee6c3"
|
|
|
|
# x11 is still manadatory - see meson.build
|
|
REQUIRED_DISTRO_FEATURES = "wayland x11 polkit"
|
|
|
|
# systemd can be replaced by libelogind (not available atow - make systemd
|
|
# mandatory distro feature)
|
|
LOGIND ?= "systemd"
|
|
REQUIRED_DISTRO_FEATURES += "systemd"
|
|
|
|
# profiler requires sysprof 3.34 which is not willing to build atow
|
|
PACKAGECONFIG ??= " \
|
|
native-backend \
|
|
${@bb.utils.contains('DISTRO_FEATURES', 'opengl x11', 'opengl glx', '', d)} \
|
|
sm \
|
|
startup-notification \
|
|
"
|
|
|
|
EXTRA_OEMESON += " \
|
|
-Dtests=false \
|
|
-Dnative_tests=false \
|
|
-Dxwayland_path=${bindir}/Xwayland \
|
|
"
|
|
|
|
# combi-config - see meson_options.txt for more details
|
|
PACKAGECONFIG[native-backend] = "-Dnative_backend=true -Dudev=true, -Dnative_backend=false -Dudev=false, libdrm virtual/libgbm libinput ${LOGIND} virtual/egl virtual/libgles2 udev"
|
|
PACKAGECONFIG[opengl] = "-Dopengl=true, -Dopengl=true, virtual/libgl"
|
|
PACKAGECONFIG[glx] = "-Dglx=true, -Dglx=false"
|
|
PACKAGECONFIG[libwacom] = "-Dlibwacom=true, -Dlibwacom=false, libwacom"
|
|
# Remove depending on pipewire-0.2 when mutter is upgraded to 3.36+
|
|
PACKAGECONFIG[remote-desktop] = "-Dremote_desktop=true, -Dremote_desktop=false, pipewire"
|
|
PACKAGECONFIG[sm] = "-Dsm=true, -Dsm=false, libsm"
|
|
PACKAGECONFIG[profiler] = "-Dprofiler=true,-Dprofiler=false,sysprof"
|
|
PACKAGECONFIG[startup-notification] = "-Dstartup_notification=true, -Dstartup_notification=false, startup-notification, startup-notification"
|
|
|
|
MUTTER_API_NAME = "mutter-10"
|
|
|
|
do_install:append() {
|
|
# Add gir links in standard paths. That makes dependents life much easier
|
|
# to find them
|
|
install -d ${D}${datadir}/gir-1.0
|
|
for gir_full in `find ${D}${libdir}/${MUTTER_API_NAME} -name '*.gir'`; do
|
|
gir=`basename "$gir_full"`
|
|
ln -sr "${D}${libdir}/${MUTTER_API_NAME}/$gir" "${D}${datadir}/gir-1.0/$gir"
|
|
done
|
|
}
|
|
|
|
GSETTINGS_PACKAGE = "${PN}-gsettings"
|
|
|
|
PACKAGES =+ "${PN}-tests ${PN}-gsettings"
|
|
|
|
FILES:${PN} += " \
|
|
${datadir}/gnome-control-center \
|
|
${libdir}/${MUTTER_API_NAME}/lib*${SOLIBS} \
|
|
${libdir}/${MUTTER_API_NAME}/*.typelib \
|
|
${libdir}/${MUTTER_API_NAME}/plugins \
|
|
"
|
|
|
|
FILES:${PN}-tests += " \
|
|
${datadir}/installed-tests \
|
|
${datadir}/${MUTTER_API_NAME}/tests \
|
|
${libexecdir}/installed-tests/${MUTTER_API_NAME} \
|
|
"
|
|
|
|
FILES:${PN}-dev += " \
|
|
${libdir}/${MUTTER_API_NAME}/*.gir \
|
|
${libdir}/${MUTTER_API_NAME}/lib*.so \
|
|
"
|
|
|
|
RDEPENDS:${PN} += "zenity ${PN}-gsettings"
|
|
|