mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-15 16:07:26 +00:00
Ross Burton
d336edb5d2
base_contains() is a compatibility wrapper and may warn in the future, so replace all instances with bb.utils.contains(). Signed-off-by: Ross Burton <ross.burton@intel.com> Signed-off-by: Martin Jansa <Martin.Jansa@gmail.com> Signed-off-by: Armin Kuster <akuster808@gmail.com>
35 lines
1.5 KiB
BlitzBasic
35 lines
1.5 KiB
BlitzBasic
SUMMARY = "Cross-platform audio output library and plugins"
|
|
DESCRIPTION = "Libao is a cross-platform audio library that allows programs to \
|
|
output audio using a simple API on a wide variety of platforms."
|
|
SECTION = "multimedia"
|
|
HOMEPAGE = "https://www.xiph.org/ao/"
|
|
|
|
LICENSE = "GPLv2"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=94d55d512a9ba36caa9b7df079bae19f"
|
|
|
|
SRC_URI="http://downloads.xiph.org/releases/ao/${BP}.tar.gz"
|
|
SRC_URI[md5sum] = "9f5dd20d7e95fd0dd72df5353829f097"
|
|
SRC_URI[sha256sum] = "03ad231ad1f9d64b52474392d63c31197b0bc7bd416e58b1c10a329a5ed89caf"
|
|
|
|
inherit autotools
|
|
|
|
PACKAGES += "${BPN}-ckport"
|
|
PACKAGES_DYNAMIC += "^${BPN}-plugin-.*"
|
|
|
|
do_install_append () {
|
|
find "${D}" -name '*.la' -exec rm -f {} +
|
|
}
|
|
|
|
python populate_packages_prepend () {
|
|
rootdir = bb.data.expand('${libdir}/ao/plugins-4', d)
|
|
rootdir_dbg = bb.data.expand('${libdir}/ao/plugins-4/.debug', d)
|
|
do_split_packages(d, rootdir, '^(.*)\.so$', output_pattern='${BPN}-plugin-%s', description='AO %s plugin')
|
|
do_split_packages(d, rootdir_dbg, '^(.*)\.so$', output_pattern='${BPN}-plugin-%s-dbg', description='AO %s plugin debug data')
|
|
}
|
|
|
|
PACKAGECONFIG ?= "${@bb.utils.contains('DISTRO_FEATURES', 'pulseaudio', 'pulseaudio', '', d)} ${@bb.utils.contains('DISTRO_FEATURES', 'alsa', 'alsa', '', d)}"
|
|
PACKAGECONFIG[esound] = "--enable-esd,--disable-esd,esound"
|
|
PACKAGECONFIG[alsa] = "--enable-alsa,--disable-alsa,alsa-lib"
|
|
PACKAGECONFIG[pulseaudio] = "--enable-pulse,--disable-pulse,pulseaudio"
|
|
FILES_${BPN}-ckport = "${libdir}/ckport"
|