mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-26 07:37:14 +00:00
Wang Mingyu
f2973002c9
Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
49 lines
1.8 KiB
BlitzBasic
49 lines
1.8 KiB
BlitzBasic
SUMMARY = "XFS Filesystem Dump Utility"
|
|
DESCRIPTION = "The xfsdump package contains xfsdump, xfsrestore and a \
|
|
number of other utilities for administering XFS filesystems.\
|
|
xfsdump examines files in a filesystem, determines which \
|
|
need to be backed up, and copies those files to a \
|
|
specified disk, tape or other storage medium."
|
|
HOMEPAGE = "http://oss.sgi.com/projects/xfs"
|
|
SECTION = "base"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://doc/COPYING;md5=15c832894d10ddd00dfcf57bee490ecc"
|
|
DEPENDS = "xfsprogs attr"
|
|
|
|
SRC_URI = "https://www.kernel.org/pub/linux/utils/fs/xfs/xfsdump/${BP}.tar.xz \
|
|
file://remove-install-as-user.patch \
|
|
file://0001-include-libgen.h-for-basename-API-prototype.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "9ca3e91055945f8a70bd4d465d5464f631630c65462896eda479d7371fd61db7"
|
|
|
|
inherit autotools-brokensep
|
|
|
|
PARALLEL_MAKE = ""
|
|
PACKAGECONFIG ??= ""
|
|
PACKAGECONFIG[gettext] = "--enable-gettext=yes,--enable-gettext=no,gettext"
|
|
|
|
CFLAGS += "-D_FILE_OFFSET_BITS=64"
|
|
TARGET_CC_ARCH:append:libc-musl = " -D_LARGEFILE64_SOURCE"
|
|
|
|
do_configure () {
|
|
export DEBUG="-DNDEBUG"
|
|
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.guess ${S}
|
|
install -m 0755 ${STAGING_DATADIR_NATIVE}/gnu-config/config.sub ${S}
|
|
oe_runconf
|
|
}
|
|
|
|
do_install () {
|
|
export DIST_ROOT=${D}
|
|
oe_runmake install
|
|
oe_runmake install-dev
|
|
if ${@bb.utils.contains('DISTRO_FEATURES','usrmerge','true','false',d)}
|
|
then
|
|
# move files from /sbin to /usr/sbin
|
|
mv -vf ${D}${exec_prefix}/../sbin/* ${D}${sbindir}
|
|
rmdir ${D}${exec_prefix}/../sbin
|
|
else
|
|
ln -sf ${base_sbindir}/xfsdump ${D}${sbindir}/xfsdump
|
|
ln -sf ${base_sbindir}/xfsrestore ${D}${sbindir}/xfsrestore
|
|
fi
|
|
}
|