mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-26 07:37:14 +00:00
Vyacheslav Yurkov
01b4e8e2b6
Target and ptest packages miss the run-time dependency, which causes the following build errors: ERROR: tbb-1_2022.3.0-r0 do_package_qa: QA Issue: /usr/lib/tbb/ptest/gnu_15.2_cxx11_64_release/test_tbbbind contained in package tbb-ptest requires libhwloc.so.15()(64bit), but no providers found in RDEPENDS:tbb-ptest? [file-rdeps] ERROR: tbb-1_2022.3.0-r0 do_package_qa: QA Issue: /usr/lib/libtbbbind_2_5.so.3.17 contained in package tbb requires libhwloc.so.15()(64bit), but no providers found in RDEPENDS:tbb? [file-rdeps] ERROR: tbb-1_2022.3.0-r0 do_package_qa: Fatal QA errors were found, failing task. Signed-off-by: Vyacheslav Yurkov <uvv.mail@gmail.com> Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
88 lines
3.7 KiB
BlitzBasic
88 lines
3.7 KiB
BlitzBasic
DESCRIPTION = "Parallelism library for C++ - runtime files \
|
|
TBB is a library that helps you leverage multi-core processor \
|
|
performance without having to be a threading expert. It represents a \
|
|
higher-level, task-based parallelism that abstracts platform details \
|
|
and threading mechanism for performance and scalability."
|
|
HOMEPAGE = "https://software.intel.com/en-us/tbb"
|
|
LICENSE = "Apache-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE.txt;md5=86d3f3a95c324c9479bd8986968f4327"
|
|
|
|
DEPENDS:append:libc-musl = " libucontext"
|
|
DEPENDS:append:class-target = " hwloc"
|
|
|
|
PE = "1"
|
|
|
|
BRANCH = "onetbb_2022"
|
|
SRCREV = "f1862f38f83568d96e814e469ab61f88336cc595"
|
|
SRC_URI = "git://github.com/oneapi-src/oneTBB.git;protocol=https;branch=${BRANCH} \
|
|
file://run-ptest \
|
|
"
|
|
|
|
LDFLAGS += "${@bb.utils.contains('DISTRO_FEATURES', 'ld-is-lld', ' -Wl,--undefined-version', '', d)}"
|
|
|
|
inherit cmake pkgconfig ptest
|
|
|
|
# test build fails, error: 'mallinfo mallinfo()' is deprecated
|
|
EXTRA_OECMAKE += " \
|
|
-DTBB_TEST=${@bb.utils.contains('PTEST_ENABLED', '1', 'ON', 'OFF', d)} \
|
|
-DCMAKE_BUILD_TYPE=Release \
|
|
-DTBB_STRICT=OFF \
|
|
-DTBB_DISABLE_HWLOC_AUTOMATIC_SEARCH=OFF \
|
|
"
|
|
|
|
RDEPENDS:${PN} += "libhwloc"
|
|
RDEPENDS:${PN}-ptest += "cmake libhwloc"
|
|
|
|
# Hard-float 'd' ABI can't be used for a target that doesn't support the D instruction set extension (ignoring target-abi)
|
|
# tmp-glibc/work/riscv64-oe-linux/tbb/1_2021.7.0-r0/recipe-sysroot-native/usr/bin/riscv64-oe-linux/riscv64-oe-linux-ld: /tmp/lto-llvm-264bc2.o: can't link soft-float modules with double-float modules
|
|
# tmp-glibc/work/riscv64-oe-linux/tbb/1_2021.7.0-r0/recipe-sysroot-native/usr/bin/riscv64-oe-linux/riscv64-oe-linux-ld: failed to merge target specific data of file /tmp/lto-llvm-264bc2.o
|
|
EXTRA_OECMAKE:append:riscv32:toolchain-clang = " -DTBB_ENABLE_IPO=OFF "
|
|
EXTRA_OECMAKE:append:riscv64:toolchain-clang = " -DTBB_ENABLE_IPO=OFF "
|
|
|
|
# fails with thumb enabled:
|
|
# | arm-oe-linux-gnueabi-g++ -march=armv7-a -mthumb -mthumb-interwork -mfloat-abi=softfp -mfpu=neon -mtune=cortex-a9 -mcpu=cortex-a9 -D__ARM__ -D__LINUX_ARM_ARCH__=7 -funwind-tables -mvectorize-with-neon-quad -rdynamic --sysroot=/OE/sysroots/m14tv -c -MMD -DTBB_USE_DEBUG -g -O0 -DUSE_PTHREAD -fPIC -D__TBB_BUILD=1 -Wall -Wno-parentheses -Wno-non-virtual-dtor -O2 -pipe -g -feliminate-unused-debug-types -fpermissive -fvisibility-inlines-hidden -I../../src -I../../src/rml/include -I../../include ../../src/tbb/concurrent_queue.cpp
|
|
# | {standard input}: Assembler messages:
|
|
# | {standard input}:250: Error: thumb conditional instruction should be in IT block -- `strexeq r2,r3,[r4]'
|
|
# ...
|
|
# | make[1]: *** [concurrent_queue.o] Error 1
|
|
ARM_INSTRUCTION_SET = "arm"
|
|
|
|
ASNEEDED = ""
|
|
|
|
LDFLAGS:append:mips = " -latomic"
|
|
LDFLAGS:append:mipsel = " -latomic"
|
|
LDFLAGS:append:riscv32:toolchain-clang = " -latomic"
|
|
|
|
LDFLAGS:append:libc-musl = " -lucontext"
|
|
|
|
# The latest version of oneTBB does not support PPC
|
|
COMPATIBLE_MACHINE:powerpc = "(!.*ppc).*"
|
|
|
|
|
|
do_install:append:class-target() {
|
|
# fix for qa check buildpaths
|
|
sed -i "s#${RECIPE_SYSROOT}##g" ${D}${libdir}/cmake/TBB/TBBTargets.cmake
|
|
}
|
|
|
|
do_install_ptest() {
|
|
install -d ${D}${PTEST_PATH}
|
|
install ${B}/test/CTestTestfile.cmake ${D}${PTEST_PATH}/
|
|
sed -i -e s#${S}#${PTEST_PATH}#g \
|
|
-e s#${B}#${PTEST_PATH}#g \
|
|
${D}${PTEST_PATH}/CTestTestfile.cmake
|
|
}
|
|
|
|
do_install_ptest:append:toolchain-gcc() {
|
|
cp -rf ${B}/gnu* ${D}${PTEST_PATH}
|
|
rm -rf ${D}${PTEST_PATH}/gnu*/libtbb*
|
|
rm -rf ${D}${PTEST_PATH}/gnu*/*.sh
|
|
}
|
|
|
|
do_install_ptest:append:toolchain-clang() {
|
|
cp -rf ${B}/clang* ${D}${PTEST_PATH}
|
|
rm -rf ${D}${PTEST_PATH}/clang*/libtbb*
|
|
rm -rf ${D}${PTEST_PATH}/clang*/*.sh
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|