mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-27 20:07:25 +00:00
Wang Mingyu
1d4b9aa359
Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
57 lines
1.9 KiB
BlitzBasic
57 lines
1.9 KiB
BlitzBasic
SUMMARY = "UPower is an abstraction for enumerating power devices"
|
|
DESCRIPTION = "UPower is an abstraction for enumerating power devices, listening to device events and querying history and statistics."
|
|
HOMEPAGE = "https://upower.freedesktop.org/"
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=0de8fbf1d97a140d1d93b9f14dcfbf08"
|
|
|
|
DEPENDS = " \
|
|
intltool-native \
|
|
libusb1 \
|
|
libgudev \
|
|
glib-2.0 \
|
|
dbus-glib \
|
|
"
|
|
|
|
SRC_URI = "https://gitlab.freedesktop.org/${BPN}/${BPN}/-/archive/v${PV}/${BPN}-v${PV}.tar.bz2"
|
|
SRC_URI[sha256sum] = "12227b3dcd34c5097bbda25984b192ea0bd5e11dce479358d9ef70415a38e4b6"
|
|
S = "${UNPACKDIR}/${BPN}-v${PV}"
|
|
|
|
UPSTREAM_CHECK_URI = "https://gitlab.freedesktop.org/${BPN}/${BPN}/-/tags"
|
|
UPSTREAM_CHECK_REGEX = "v(?P<pver>\d+(\.\d+)+)"
|
|
|
|
GIR_MESON_ENABLE_FLAG = "enabled"
|
|
GIR_MESON_DISABLE_FLAG = "disabled"
|
|
GTKDOC_MESON_OPTION = "gtk-doc"
|
|
|
|
inherit meson pkgconfig gtk-doc gettext gobject-introspection systemd
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd polkit', d)}"
|
|
PACKAGECONFIG[idevice] = "-Didevice=enabled,-Didevice=disabled,libimobiledevice libplist"
|
|
PACKAGECONFIG[systemd] = "-Dsystemdsystemunitdir=${systemd_system_unitdir},-Dsystemdsystemunitdir=no -Dudevrulesdir=${base_libdir}/udev/rules.d,systemd"
|
|
PACKAGECONFIG[polkit] = "-Dpolkit=enabled,-Dpolkit=disabled,polkit"
|
|
|
|
EXTRA_OEMESON = " \
|
|
-Dos_backend=linux \
|
|
-Dman=false \
|
|
"
|
|
|
|
SYSTEMD_SERVICE:${PN} = "upower.service"
|
|
# don't start on boot by default - dbus does that on demand
|
|
SYSTEMD_AUTO_ENABLE = "disable"
|
|
|
|
RDEPENDS:${PN} += "${VIRTUAL-RUNTIME_dbus}"
|
|
RRECOMMENDS:${PN} += "pm-utils"
|
|
PACKAGES += "${PN}-zsh-completion"
|
|
FILES:${PN} += " \
|
|
${datadir}/dbus-1/ \
|
|
${datadir}/polkit-1/ \
|
|
${base_libdir}/udev/* \
|
|
"
|
|
FILES:${PN}-zsh-completion = "${datadir}/zsh"
|
|
|
|
do_install:append() {
|
|
# remove integration tests scripts
|
|
rm -rf ${D}${datadir}/installed-tests
|
|
rm -rf ${D}${libexecdir}/upower
|
|
}
|