mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-10-21 20:19:33 +00:00
Khem Raj
ca912668df
Upstream changes (CHANGELOG.md, 1.4.2): * Require C11 for compilation (public headers remain C99). * avifgainmaputil: add --jobs flag for multi-threaded read/write and enable auto tiling; use AOM_TUNE_IQ for layered inter-frame encoding. * Fix memory leak of altICC on early return; avoid MT loop-restoration crash with libaom < 3.13.3; fix decoding of layered images with multiple scaled alpha layers; fix NaN bypass of AVIF_CLAMP in gain-map tone mapping; fix NULL deref in avifImageCopy(). * Refreshed bundled dependency pins (aom v3.14.1, libyuv, libpng 1.6.58, etc.) - not used here; the recipe fetches libargparse/libyuv at their own pinned SRCREVs. Version-only bump of SRCREV_libavif; sub-source SRCREVs unchanged. Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
34 lines
1.7 KiB
BlitzBasic
34 lines
1.7 KiB
BlitzBasic
SUMMARY = "This library aims to be a friendly, portable C implementation of the AV1 Image File Format"
|
|
HOMEPAGE = "https://github.com/AOMediaCodec/libavif"
|
|
SECTION = "libs"
|
|
# Most is the code is under BSD-2, but libyuv is under BSD-3, and iccjpeg is under IJG
|
|
LICENSE = "BSD-2-Clause AND BSD-3-Clause AND IJG"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=51549db0941829faeedcc86efec2f4c0"
|
|
|
|
SRC_URI = "git://github.com/AOMediaCodec/libavif.git;protocol=https;branch=main;tag=v${PV};name=libavif"
|
|
SRC_URI += "git://github.com/kmurray/libargparse.git;protocol=https;nobranch=1;name=libargparse;subdir=${S}/ext/libargparse"
|
|
SRC_URI += "git://chromium.googlesource.com/libyuv/libyuv;protocol=https;nobranch=1;name=libyuv;subdir=${S}/ext/libyuv"
|
|
SRCREV_libavif = "c5240fc79fe5c2407e10afd35f5505ef6333ea49"
|
|
SRCREV_libargparse = "ee74d1b53bd680748af14e737378de57e2a0a954"
|
|
SRCREV_libyuv = "6067afde563c3946eebd94f146b3824ab7a97a9c"
|
|
SRCREV_FORMAT = "libavif"
|
|
|
|
DEPENDS = "nasm-native"
|
|
|
|
inherit cmake pkgconfig
|
|
|
|
EXTRA_OECMAKE += " \
|
|
-DAVIF_BUILD_MAN_PAGES=OFF \
|
|
-DAVIF_LIBYUV=LOCAL \
|
|
"
|
|
|
|
PACKAGECONFIG ?= "dav1d gdk-pixbuf"
|
|
PACKAGECONFIG[apps] = "-DAVIF_BUILD_APPS=ON -DAVIF_LIBXML2=SYSTEM,-DAVIF_BUILD_APPS=OFF -DAVIF_LIBXML2=OFF,zlib libjpeg-turbo libpng libwebp libxml2"
|
|
PACKAGECONFIG[gdk-pixbuf] = "-DAVIF_BUILD_GDK_PIXBUF=ON,-DAVIF_BUILD_GDK_PIXBUF=OFF,gdk-pixbuf"
|
|
PACKAGECONFIG[aom] = "-DAVIF_CODEC_AOM=SYSTEM,-DAVIF_CODEC_AOM=OFF,aom"
|
|
PACKAGECONFIG[dav1d] = "-DAVIF_CODEC_DAV1D=SYSTEM,-DAVIF_CODEC_DAV1D=OFF,dav1d"
|
|
PACKAGECONFIG[rav1e] = "-DAVIF_CODEC_RAV1E=SYSTEM,-DAVIF_CODEC_RAV1E=OFF,librav1e"
|
|
PACKAGECONFIG[svt] = "-DAVIF_CODEC_SVT=SYSTEM,-DAVIF_CODEC_SVT=OFF,svt-av1"
|
|
|
|
FILES:${PN} += "${libdir}/gdk-pixbuf-2.0 ${datadir}"
|