mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-17 04:37:19 +00:00
Markus Volk
d29b453950
After the recent recipe update I see this build error: | Makefile.linux:67: config.mk: No such file or directory | make: *** No rule to make target '/configure', needed by 'config.mk'. Stop. Run the configure script so that config.mk gets created Also fix LIC_FILE_CHECKSUM. Copyright year has been changed Signed-off-by: Markus Volk <f_l_k@t-online.de> Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
55 lines
2.0 KiB
BlitzBasic
55 lines
2.0 KiB
BlitzBasic
SUMMARY = "Lightweight UPnP IGD daemon"
|
|
DESCRIPTION = "The miniUPnP daemon is an UPnP IGD (internet gateway device) \
|
|
which provide NAT traversal services to any UPnP enabled client on \
|
|
the network."
|
|
|
|
SECTION = "networking"
|
|
LICENSE = "BSD-3-Clause"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=9526418307cb153aee96a4f9b33bd1c7"
|
|
|
|
inherit gettext pkgconfig systemd
|
|
|
|
DEPENDS += "iptables net-tools util-linux libmnl libnetfilter-conntrack openssl"
|
|
|
|
SRC_URI = "http://miniupnp.tuxfamily.org/files/download.php?file=${BP}.tar.gz;downloadfilename=${BP}.tar.gz \
|
|
file://miniupnpd.service \
|
|
"
|
|
SRC_URI[sha256sum] = "f9c34ed3632fb60cd248dd5897bd98479a103a75688b056ca2f069e68ab32987"
|
|
|
|
UPSTREAM_CHECK_URI = "https://miniupnp.tuxfamily.org/files/"
|
|
UPSTREAM_CHECK_REGEX = "${BPN}-(?P<pver>\d+(\.\d+)+)\.tar"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}"
|
|
PACKAGECONFIG[ipv6] = "--ipv6"
|
|
|
|
EXTRA_OEMAKE = "-f Makefile.linux"
|
|
|
|
do_configure() {
|
|
echo "${@d.getVar('DISTRO_VERSION')}" > ${S}/os.openembedded
|
|
./configure
|
|
CONFIG_OPTIONS="--leasefile --vendorcfg ${PACKAGECONFIG_CONFARGS}" oe_runmake --always-make config.h
|
|
}
|
|
|
|
do_compile() {
|
|
oe_runmake
|
|
}
|
|
|
|
do_install() {
|
|
install -d ${D}/${sbindir}
|
|
install ${S}/miniupnpd ${D}/${sbindir}
|
|
install -d ${D}/${sysconfdir}/${BPN}
|
|
install ${S}/netfilter/iptables_init.sh ${D}/${sysconfdir}/${BPN}
|
|
install ${S}/netfilter/iptables_removeall.sh ${D}/${sysconfdir}/${BPN}
|
|
install ${S}/netfilter/ip6tables_init.sh ${D}/${sysconfdir}/${BPN}
|
|
install ${S}/netfilter/miniupnpd_functions.sh ${D}/${sysconfdir}/${BPN}
|
|
install ${S}/netfilter/ip6tables_removeall.sh ${D}/${sysconfdir}/${BPN}
|
|
install -m 0644 -b ${S}/miniupnpd.conf ${D}/${sysconfdir}/${BPN}
|
|
install -d ${D}/${sysconfdir}/init.d
|
|
install ${S}/linux/miniupnpd.init.d.script ${D}/${sysconfdir}/init.d/miniupnpd
|
|
|
|
install -d ${D}${systemd_unitdir}/system
|
|
install -m 0644 ${UNPACKDIR}/miniupnpd.service ${D}${systemd_unitdir}/system/
|
|
}
|
|
|
|
SYSTEMD_SERVICE:${PN} = "miniupnpd.service"
|