mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-17 04:37:19 +00:00
Khem Raj
bc404033bb
The webkit2gtk pkg-config check was unconditional, but WEBKIT is only used by the GNOME auth dialog. Move it under the with-gnome guard add webkitgtk3 to the gnome PACKAGECONFIG deps ship the D-Bus system policy file. Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
51 lines
1.6 KiB
BlitzBasic
51 lines
1.6 KiB
BlitzBasic
SUMMARY = "OpenConnect VPN client for NetworkManager"
|
|
SECTION = "net/misc"
|
|
|
|
LICENSE = "GPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=186e8b54342da4f753a62b7748c947db"
|
|
|
|
DEPENDS = "glib-2.0-native intltool-native libxml2 networkmanager openconnect"
|
|
|
|
GNOMEBASEBUILDCLASS = "autotools"
|
|
inherit gnomebase useradd
|
|
|
|
SRC_URI = "${GNOME_MIRROR}/NetworkManager-openconnect/${@gnome_verdir("${PV}")}/NetworkManager-openconnect-${PV}.tar.xz \
|
|
file://0001-configure-only-require-webkit2gtk-when-building-the-a.patch \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "844b6bf64ecadb97b4a68c776db89aa5e6ee7e59bd24b0180228406863136464"
|
|
|
|
S = "${UNPACKDIR}/NetworkManager-openconnect-${PV}"
|
|
|
|
# meta-gnome in layers is required using gnome:
|
|
PACKAGECONFIG[gnome] = "--with-gnome,--without-gnome,gtk+3 gcr3 libnma libsecret webkitgtk3,"
|
|
PACKAGECONFIG[gtk4] = "--with-gtk4,--without-gtk4,gtk4,"
|
|
|
|
do_configure:append() {
|
|
# network-manager-openconnect.metainfo.xml is created in source folder but
|
|
# compile expects it in build folder. As long as nobody comes up with a
|
|
# better solution just support build:
|
|
if [ -e ${S}/appdata/network-manager-openconnect.metainfo.xml ]; then
|
|
mkdir -p ${B}/appdata
|
|
cp -f ${S}/appdata/network-manager-openconnect.metainfo.xml ${B}/appdata/
|
|
fi
|
|
}
|
|
|
|
USERADD_PACKAGES = "${PN}"
|
|
USERADD_PARAM:${PN} = "--system nm-openconnect"
|
|
|
|
FILES:${PN} += " \
|
|
${libdir}/NetworkManager/*.so \
|
|
${nonarch_libdir}/NetworkManager/VPN/nm-openconnect-service.name \
|
|
${datadir}/dbus-1/system.d \
|
|
"
|
|
|
|
FILES:${PN}-staticdev += " \
|
|
${libdir}/NetworkManager/*.a \
|
|
"
|
|
|
|
RDEPENDS:${PN} = " \
|
|
networkmanager \
|
|
openconnect \
|
|
"
|