mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-10-23 20:58:33 +00:00
Khem Raj
c3683a2d3e
Bump to the upstream 2.66 orig tarball (now .orig.tar.gz instead of .orig.tar.bz2) from Debian. - ssmtp-bug584162-fix.patch dropped: the fix (dropping trailing '\r' in standardise() and the header_parse() EOF/empty-header handling) is already present verbatim in the 2.66 source. - 0001-ssmtp-Correct-the-null-pointer-assignment-to-char-po.patch dropped: upstream already initializes all the char pointers with NULL instead of (char)NULL. - 0001-Fix-incompatible-pointer-types-error-with-gcc-15.patch rebased: the call site already casts to (sighandler_t)handler in 2.66, so only the handler() signature hunk is still needed; the call-site hunk was dropped as it no longer applies and is unnecessary once the signature takes an int. - use-DESTDIR.patch rebased: upstream 2.66 already appends $(LDFLAGS) in the ssmtp link rule, so that hunk was dropped; the DESTDIR hunks for install/uninstall are still needed and were regenerated against the new Makefile.in. - build-ouside_srcdir.patch and 0001-include-libgen.h-for-basename.patch kept unchanged, still needed, apply cleanly. Build-verified: ssmtp builds and packages successfully. AI-Generated: Uses Claude Code Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
44 lines
1.5 KiB
BlitzBasic
44 lines
1.5 KiB
BlitzBasic
SUMMARY = "extremely simple MTA to get mail off the system to a mail hub"
|
|
HOMEPAGE = "http://packages.qa.debian.org/s/ssmtp.html"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=0c56db0143f4f80c369ee3af7425af6e"
|
|
|
|
SRC_URI = "${DEBIAN_MIRROR}/main/s/${BPN}/${BPN}_${PV}.orig.tar.gz \
|
|
file://build-ouside_srcdir.patch \
|
|
file://use-DESTDIR.patch \
|
|
file://0001-include-libgen.h-for-basename.patch \
|
|
file://0001-Fix-incompatible-pointer-types-error-with-gcc-15.patch \
|
|
"
|
|
|
|
SRC_URI[md5sum] = "f9894703fcc559f63cffacfea08f9b75"
|
|
SRC_URI[sha256sum] = "6e639eafce4c8a3b7782c2a8a2d467be097c5896eae86fcde0f608666ea88249"
|
|
|
|
inherit autotools update-alternatives
|
|
|
|
PACKAGECONFIG ?= "ssl ${@bb.utils.filter('DISTRO_FEATURES', 'ipv6', d)}"
|
|
|
|
PACKAGECONFIG[ssl] = "--enable-ssl,--disable-ssl,openssl"
|
|
PACKAGECONFIG[ipv6] = "--enable-inet6,--disable-inet6"
|
|
|
|
EXTRA_OECONF += "--mandir=${mandir}"
|
|
|
|
EXTRA_OEMAKE = "GEN_CONFIG='/bin/true'"
|
|
|
|
LDFLAGS += "${@bb.utils.contains('PACKAGECONFIG', 'ssl', '-lssl -lcrypto', '', d)}"
|
|
|
|
do_install:append () {
|
|
install -d ${D}${mandir}/
|
|
mv ${D}${exec_prefix}/man/* ${D}${mandir}/
|
|
rmdir ${D}${exec_prefix}/man
|
|
ln -s ssmtp ${D}${sbindir}/sendmail
|
|
ln -s ssmtp ${D}${sbindir}/newaliases
|
|
ln -s ssmtp ${D}${sbindir}/mailq
|
|
}
|
|
|
|
ALTERNATIVE_PRIORITY_${PN} = "100"
|
|
|
|
ALTERNATIVE:${PN} = "mailq newaliases sendmail"
|
|
ALTERNATIVE_LINK_NAME[sendmail] = "${sbindir}/sendmail"
|
|
ALTERNATIVE_LINK_NAME[newaliases] = "${sbindir}/newaliases"
|
|
ALTERNATIVE_LINK_NAME[mailq] = "${sbindir}/mailq"
|