mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-27 07:57:27 +00:00
Moritz Haase
1911d0d2fc
There hasn't been a new upstream release yet that ships the required changes. Signed-off-by: Moritz Haase <Moritz.Haase@bmw.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
34 lines
1.2 KiB
BlitzBasic
34 lines
1.2 KiB
BlitzBasic
DESCRIPTION = "ZeroMQ looks like an embeddable networking library but acts like a concurrency framework"
|
|
HOMEPAGE = "http://www.zeromq.org"
|
|
LICENSE = "MPL-2.0"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=9741c346eef56131163e13b9db1241b3"
|
|
|
|
PACKAGECONFIG ??= "libsodium"
|
|
PACKAGECONFIG[libsodium] = "-DWITH_LIBSODIUM=ON,-DWITH_LIBSODIUM=OFF, libsodium"
|
|
|
|
SRC_URI = "http://github.com/zeromq/libzmq/releases/download/v${PV}/zeromq-${PV}.tar.gz \
|
|
file://0001-CMakeLists-txt-Avoid-host-specific-path-to-libsodium.patch \
|
|
file://0002-cmake_minimum_required-before-project.patch \
|
|
file://0003-set-upper-bound-in-cmake_minimum_required.patch \
|
|
file://run-ptest \
|
|
"
|
|
SRC_URI[sha256sum] = "6653ef5910f17954861fe72332e68b03ca6e4d9c7160eb3a8de5a5a913bfab43"
|
|
|
|
UPSTREAM_CHECK_URI = "https://github.com/${BPN}/libzmq/releases"
|
|
UPSTREAM_CHECK_REGEX = "releases/tag/v(?P<pver>\d+\.\d+\.\d+)"
|
|
|
|
inherit cmake ptest pkgconfig
|
|
|
|
EXTRA_OECMAKE = "${@bb.utils.contains('PTEST_ENABLED', '1', '-DBUILD_TESTS=ON', '-DBUILD_TESTS=OFF', d)} \
|
|
-DCMAKE_SKIP_RPATH=ON \
|
|
"
|
|
|
|
do_install_ptest () {
|
|
install -d ${D}${PTEST_PATH}/tests
|
|
install -m 0755 ${B}/bin/test_* ${D}${PTEST_PATH}/tests
|
|
}
|
|
|
|
FILES:${PN}-doc += "${datadir}/zmq/*.txt"
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|