mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-01-12 03:24:08 +00:00
fc78d37ff0
Please see https://git.yoctoproject.org/poky/commit/?id=4dd321f8b83afecd962393101b2a6861275b5265 for what changes are needed, and sed commands that can be used to make them en masse. I've verified that bitbake -c patch world works with these, but did not run a world build; the majority of recipes shouldn't need further fixups, but if there are some that still fall out, they can be fixed in followups. Signed-off-by: Alexander Kanavin <alex@linutronix.de> Signed-off-by: Khem Raj <raj.khem@gmail.com>
46 lines
1.6 KiB
BlitzBasic
46 lines
1.6 KiB
BlitzBasic
SUMMARY = "A text-based user interface plugin of dnf for user to manage packages. "
|
|
LICENSE = "GPL-2.0-only"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=b234ee4d69f5fce4486a80fdaf4a4263"
|
|
|
|
SRC_URI = "git://github.com/ubinux/dnf-plugin-tui.git;branch=master;protocol=https"
|
|
SRCREV = "ad48d934c54ab01026634c90f47f151f148b8147"
|
|
|
|
SRC_URI:append:class-target = " file://oe-remote.repo.sample"
|
|
|
|
inherit setuptools3-base
|
|
|
|
|
|
do_install:append() {
|
|
install -d ${D}${datadir}/dnf
|
|
install -m 0755 ${S}/samples/* ${D}${datadir}/dnf
|
|
install -d ${D}${PYTHON_SITEPACKAGES_DIR}/dnf-plugins/mkimg
|
|
install -m 0755 ${S}/dnf-plugins/mkimg/* ${D}${PYTHON_SITEPACKAGES_DIR}/dnf-plugins/mkimg
|
|
for file in $(ls ${S}/dnf-plugins/ | grep -v mkimg); do
|
|
install -m 0755 ${S}/dnf-plugins/$file ${D}${PYTHON_SITEPACKAGES_DIR}/dnf-plugins
|
|
done
|
|
}
|
|
|
|
do_install:append:class-target() {
|
|
install -d ${D}${sysconfdir}/yum.repos.d
|
|
install -m 0644 ${UNPACKDIR}/oe-remote.repo.sample ${D}${sysconfdir}/yum.repos.d
|
|
}
|
|
|
|
do_install:append:class-nativesdk() {
|
|
install -d -p ${D}/${SDKPATH}/postinst-intercepts
|
|
cp -r ${COREBASE}/scripts/postinst-intercepts/* ${D}/${SDKPATH}/postinst-intercepts/
|
|
sed -i -e 's/STAGING_DIR_NATIVE/NATIVE_ROOT/g' ${D}/${SDKPATH}/postinst-intercepts/*
|
|
}
|
|
|
|
FILES:${PN} += "${datadir}/dnf"
|
|
FILES:${PN} += "${SDKPATH}/postinst-intercepts"
|
|
|
|
RDEPENDS:${PN} += " \
|
|
bash \
|
|
dnf \
|
|
libnewt-python \
|
|
"
|
|
BBCLASSEXTEND = "nativesdk"
|
|
|
|
SKIP_RECIPE[dnf-plugin-tui] ?= "${@bb.utils.contains('PACKAGE_CLASSES', 'package_rpm', '', 'does not build correctly without package_rpm in PACKAGE_CLASSES', d)}"
|