mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-10-23 20:58:33 +00:00
Khem Raj
f1fc1f3908
All 6 ptest failures (t/31methcache, t/35thrclone, t/40profile, t/41prof_dump, t/42prof_data, t/43prof_env) are missing runtime perl modules, in two groups: Module::Load, required by DBI/Profile.pm line 682: Can't locate Module/Load.pm in @INC ... at /usr/lib/perl5/vendor_perl/5.44.0/aarch64-linux/DBI/Profile.pm line 682. This breaks t/40profile and t/43prof_env directly, and cascades into t/41prof_dump and t/42prof_data: once DBI/Profile.pm fails to compile, %INC is poisoned, so those two report "Attempt to reload DBI/Profile.pm aborted" and a missing DBI::Profile->flush_to_disk method rather than the underlying cause. Provided by perl-module-load. Test2::Util::Sig, required by Test2/IPC/Driver/Files.pm line 18, which Test::Builder pulls in when a test enables Test2 IPC (threads/forking): Can't locate Test2/Util/Sig.pm in @INC ... at /usr/lib/perl5/5.44.0/Test2/IPC/Driver/Files.pm line 18. This makes Test::More unusable in t/31methcache and t/35thrclone, which is why only those two of the many Test::More-based tests fail. Provided by perl-module-test2-util-sig. Signed-off-by: Khem Raj <raj.khem@gmail.com>
71 lines
2.0 KiB
BlitzBasic
71 lines
2.0 KiB
BlitzBasic
SUMMARY = "The Perl Database Interface"
|
|
DESCRIPTION = "DBI is a database access Application Programming Interface \
|
|
(API) for the Perl Language. The DBI API Specification defines a set \
|
|
of functions, variables and conventions that provide a consistent \
|
|
database interface independent of the actual database being used. \
|
|
"
|
|
HOMEPAGE = "https://metacpan.org/dist/DBI"
|
|
SECTION = "libs"
|
|
LICENSE = "Artistic-1.0 OR GPL-1.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=1a1138dff61f77bbc3d8782caba6758d"
|
|
|
|
SRC_URI = "${CPAN_MIRROR}/authors/id/H/HM/HMBRAND/DBI-${PV}.tgz"
|
|
SRC_URI[sha256sum] = "da621a23fa68e1e04fac824cfd3d41e8ffbab2ab3eba642a12499242e8be5253"
|
|
|
|
S = "${UNPACKDIR}/DBI-${PV}"
|
|
|
|
inherit cpan ptest-perl
|
|
|
|
do_install:prepend() {
|
|
# test requires "-T" (taint) command line option
|
|
rm -rf ${B}/t/pod-coverage.t
|
|
rm -rf ${B}/t/13taint.t
|
|
# source of test failure not obvious
|
|
rm -rf ${B}/t/85gofer.t
|
|
# unclear why there are several duplicates of tests in tarball
|
|
rm -rf ${B}/t/z*.t
|
|
}
|
|
|
|
do_install:append() {
|
|
sed -i "s:^#!.*:#!/usr/bin/env perl:" ${D}${bindir}/dbiproxy \
|
|
${D}${bindir}/dbiprof ${D}${bindir}/dbilogstrip
|
|
}
|
|
|
|
RDEPENDS:${PN}:class-target = " \
|
|
perl \
|
|
perl-module-carp \
|
|
perl-module-exporter \
|
|
perl-module-exporter-heavy \
|
|
perl-module-dynaloader \
|
|
perl-module-io-dir \
|
|
perl-module-scalar-util \
|
|
perl-module-universal \
|
|
"
|
|
|
|
RDEPENDS:${PN}-ptest += " \
|
|
perl-module-b \
|
|
perl-module-benchmark \
|
|
perl-module-cwd \
|
|
perl-module-data-dumper \
|
|
perl-module-encode \
|
|
perl-module-encode-byte \
|
|
perl-module-encode-encoding \
|
|
perl-module-file-copy \
|
|
perl-module-file-path \
|
|
perl-module-lib \
|
|
perl-module-load \
|
|
perl-module-perlio \
|
|
perl-module-perlio-encoding \
|
|
perl-module-perlio-scalar \
|
|
perl-module-perlio-via \
|
|
perl-module-sdbm-file \
|
|
perl-module-storable \
|
|
perl-module-test-more \
|
|
perl-module-test2-ipc-driver \
|
|
perl-module-test2-util-sig \
|
|
perl-module-threads \
|
|
perl-module-utf8 \
|
|
"
|
|
|
|
BBCLASSEXTEND = "native"
|