mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-27 07:57:27 +00:00
Khem Raj
dc2335d63b
xterm do_configure runs gnu-configize (to refresh config.sub/config.guess), newer versions of gnu-config needs to specify the directory for configure scripts Fixes a build error abort in do_configure: gnu-configize: error: 'configure.ac' is required Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
53 lines
1.9 KiB
BlitzBasic
53 lines
1.9 KiB
BlitzBasic
require recipes-graphics/xorg-app/xorg-app-common.inc
|
|
SUMMARY = "xterm is the standard terminal emulator for the X Window System"
|
|
DEPENDS = "libxaw xorgproto libxext libxau libxinerama libxpm ncurses desktop-file-utils-native"
|
|
|
|
LIC_FILES_CHKSUM = "file://xterm.h;beginline=3;endline=31;md5=413ff95100710d7a817c5257bf3940cb"
|
|
|
|
SRC_URI = "http://invisible-mirror.net/archives/${BPN}/${BP}.tgz \
|
|
file://0001-include-missing-pty.h-header-for-openpty.patch \
|
|
"
|
|
SRC_URI[sha256sum] = "7ba9fbb303dd3d95d06ca24360d019048d84e5822dc6fe722cd77369bdbf231f"
|
|
|
|
PACKAGECONFIG ?= ""
|
|
PACKAGECONFIG[xft] = "--enable-freetype,--disable-freetype,libxft fontconfig freetype-native"
|
|
|
|
# Let xterm install .desktop files
|
|
inherit mime-xdg
|
|
|
|
EXTRA_OECONF = " --x-includes=${STAGING_INCDIR} \
|
|
--x-libraries=${STAGING_LIBDIR} \
|
|
FREETYPE_CONFIG=${STAGING_BINDIR_CROSS}/freetype-config \
|
|
--disable-imake \
|
|
--disable-rpath-hack \
|
|
--disable-setuid \
|
|
--with-app-defaults=${datadir}/X11/app-defaults \
|
|
--program-transform-name= \
|
|
"
|
|
|
|
B = "${S}"
|
|
|
|
CFLAGS += "-D_GNU_SOURCE"
|
|
|
|
do_configure() {
|
|
gnu-configize --force ${S}
|
|
sed -e "s%/usr/contrib/X11R6%${STAGING_LIBDIR}%g" -i ${S}/configure
|
|
oe_runconf
|
|
}
|
|
|
|
do_install:append() {
|
|
oe_runmake install-desktop DESTDIR="${D}" DESKTOP_FLAGS="--dir=${D}${DESKTOPDIR}"
|
|
}
|
|
|
|
RPROVIDES:${PN} = "virtual-x-terminal-emulator"
|
|
|
|
# busybox can supply resize too
|
|
inherit update-alternatives
|
|
|
|
ALTERNATIVE:${PN} = "resize x-terminal-emulator"
|
|
ALTERNATIVE_TARGET[x-terminal-emulator] = "${bindir}/xterm"
|
|
# rxvt-unicode defaults to priority 10. Let's be one point lower to let it override xterm.
|
|
ALTERNATIVE_PRIORITY[x-terminal-emulator] = "9"
|
|
|
|
CVE_STATUS[CVE-1999-0965] = "cpe-incorrect: Current version (392) not affected. This was fixed in version X11R5-fix-26 (R11R6 from 1994)"
|