mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-17 04:37:19 +00:00
Khem Raj
496ce81934
The bundled gdb 16.2 hard-requires GMP and MPFR (crash 8.0.6 bundled gdb 10.2,
which did not). native.bbclass remaps DEPENDS to their -native variants
automatically, so crash-native builds, but cross.bbclass does not - so
crash-cross failed in gdb's configure with:
configure: error: Building GDB requires GMP 4.2+, and MPFR 3.1.0+.
List the build-host dependencies (gmp/mpfr, plus readline/ncurses that crash
links) explicitly for class-cross.
Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
33 lines
1.1 KiB
BlitzBasic
33 lines
1.1 KiB
BlitzBasic
require crash.inc
|
|
|
|
BBCLASSEXTEND = "native cross"
|
|
|
|
EXTRA_OEMAKE:class-cross = 'RPMPKG="${PV}" \
|
|
GDB_TARGET="${BUILD_SYS} --target=${TARGET_SYS}" \
|
|
GDB_HOST="${BUILD_SYS}" \
|
|
GDB_MAKE_JOBS="${PARALLEL_MAKE}" \
|
|
'
|
|
|
|
EXTRA_OEMAKE:append:class-native = " LDFLAGS='${BUILD_LDFLAGS}'"
|
|
EXTRA_OEMAKE:append:class-cross = " LDFLAGS='${BUILD_LDFLAGS}'"
|
|
|
|
# gdb 16.2 (bundled, built for the build host in the cross case) needs gmp and
|
|
# mpfr, and crash links readline/ncurses. Unlike native.bbclass, cross.bbclass
|
|
# does not remap DEPENDS to their -native variants, so list them explicitly.
|
|
DEPENDS:append:class-cross = " zlib-native readline-native ncurses-native gmp-native mpfr-native"
|
|
|
|
do_install:class-target () {
|
|
oe_runmake DESTDIR=${D} install
|
|
}
|
|
|
|
do_install:class-native () {
|
|
oe_runmake DESTDIR=${D}${STAGING_DIR_NATIVE} install
|
|
}
|
|
|
|
do_install:class-cross () {
|
|
install -m 0755 ${S}/crash ${D}/${bindir}
|
|
}
|
|
|
|
RDEPENDS:${PN}:class-native = ""
|
|
RDEPENDS:${PN}:class-cross = ""
|