mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-25 07:17:05 +00:00
Wang Mingyu
a55c8391a4
License-Update: Copyright year updated to 2026 Changelog: ============= * Added CTAP 2.3 support. * Restrict webauthn.dll search paths; YSA-2026-01. * Support application-managed PIN/UV Auth tokens; gh#806. * Support 64-byte hmac-secret salts when using windows://hello. * Fixed a U2F transaction handling bug when a timeout had been set; gh#917. * Fixed a bug where stdin was closed on fido_nl_new failure; gh#923. * fido2-token: new -G -t mode to to retrieve a PPUAT. * fido2-token: new -I -t mode for deciphering encrypted fields. * fido2-cred -M: support the -t toggle argument * Improved documentation and examples. * Removed tools from SDK packaging on Windows. * New API calls Signed-off-by: Wang Mingyu <wangmy@fujitsu.com> Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
41 lines
1.7 KiB
BlitzBasic
41 lines
1.7 KiB
BlitzBasic
SUMMARY = "FIDO 2.0 support library"
|
|
DESCRIPTION = "libfido2 provides library functionality and command-line tools to \
|
|
communicate with a FIDO device over USB, and to verify attestation and \
|
|
assertion signatures."
|
|
HOMEPAGE = "https://developers.yubico.com/libfido2"
|
|
LICENSE = "BSD-2-Clause"
|
|
SECTION = "libs/network"
|
|
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=81b68c65611c3a2eaac9e44814284719"
|
|
|
|
SRC_URI = "https://developers.yubico.com/${BPN}/Releases/${BPN}-${PV}.tar.gz"
|
|
SRC_URI[sha256sum] = "c1012c8871d71b65872fd5ff1a9d6b0838a55683a03e85ba97479ce57129c736"
|
|
|
|
inherit nopackages
|
|
|
|
PACKAGES = ""
|
|
|
|
# The purpose of this recipe is to break a circular dependency between libfido2 and
|
|
# systemd. libfido2 depends on udev (provided by systemd) to build, while systemd
|
|
# depends on libfido2 if the fido feature is enabled. However, systemd doesn't
|
|
# actually link against libfido2. It only needs the headers in place and a dummy
|
|
# shared library. It opportunistically dlopens libfido2 if it's present, but
|
|
# for that to work it needs the headers in place.
|
|
# Just fake enough to make systemd happy, and have it RRECOMMEND the real libfido2.
|
|
do_install() {
|
|
mkdir -p ${D}${includedir}/libfido2-initial/fido
|
|
mkdir -p ${D}${datadir}/pkgconfig
|
|
|
|
install -m 644 ${S}/src/fido.h ${D}${includedir}/libfido2-initial
|
|
install -m 644 ${S}/src/fido/* ${D}${includedir}/libfido2-initial/fido/
|
|
|
|
# Real libfido2 installs its pkg conf file in ${libdir}.
|
|
sed -e 's,@CMAKE_INSTALL_PREFIX@,${exec_prefix},' \
|
|
-e 's,@CMAKE_INSTALL_LIBDIR@,${baselib}/libfido2-initial,' \
|
|
-e 's,@FIDO_VERSION@,${PV},' \
|
|
-e 's,@PROJECT_NAME@,${BPN},' \
|
|
-e '/^Cflags/s,$,/libfido2-initial,' \
|
|
${S}/src/libfido2.pc.in > ${D}${datadir}/pkgconfig/libfido2.pc
|
|
|
|
}
|