mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-06-01 13:40:04 +00:00
Jason Schonberg
9e2a1261e7
Changes in release 0.34.2 (neon-0.34.2.tar.gz), 15th April 2025
Fix regression in NTLM auth in 0.34.0 (issue #190).
Add docs for ne_ssl_proto_name, ne_ssl_protovers, ne_get_request_target.
Changes in release 0.34.1 (neon-0.34.1.tar.gz), 14th April 2025
Fix regression in 207 parsing of elements which omit a reason-phrase (issue #188).
Fix ne_move() to submit lock tokens for the parent collection of a source resource locked with depth: 0.
Changes in release 0.34.0 (neon-0.34.0.tar.gz), 23rd November 2024
Interface changes:
API and ABI backwards-compatible with 0.27.x and later
NE_SESSFLAG_SSLv2 is now ignored
New interfaces and features:
ne_request.h: add ne_get_response_location(), add ne_get_request_target()
ne_redirect.h: adds relative URI resolution per RFC 9110
ne_socket.h: add ne_iaddr_set_scope(), ne_iaddr_get_scope(), ne_sock_getproto()
ne_session.h: add NE_SESSFLAG_STRICT session flag
ne_session.h: ne_session_create() now accepts scoped IPv6 link-local literal addresses following the RFC 6874 syntax;
ne_session.h: add ne_ssl_set_protovers() to configure TLS protocol version ranges
ne_utils.h: add NE_FEATURE_GSSAPI, NE_FEATURE_LIBPXY feature flags
ne_ssl.h: add ne_ssl_proto_name()
HTTP strictness/compliance updated for RFC 9110/9112; notably stricter in parsing header field line, chunked transfer-coding, status-line.
Bug fixes:
auth: the ‘realm’ string passed to credentials callback is now cleaned of non-printable characters.
Documentation & header updates for RFC 9110/9112.
New NE_MINIMUM_VERSION() autoconf macro for better version handling.
Signed-off-by: Jason Schonberg <schonm@gmail.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
61 lines
2.0 KiB
BlitzBasic
61 lines
2.0 KiB
BlitzBasic
SUMMARY = "An HTTP and WebDAV client library with a C interface"
|
|
HOMEPAGE = "https://notroj.github.io/neon/"
|
|
SECTION = "libs"
|
|
LICENSE = "LGPL-2.0-or-later"
|
|
LIC_FILES_CHKSUM = "file://src/COPYING.LIB;md5=f30a9716ef3762e3467a2f62bf790f0a \
|
|
file://src/ne_utils.h;beginline=1;endline=20;md5=34c8e338bfa0237561e68d30c3c71133"
|
|
|
|
SRC_URI = "https://notroj.github.io/neon/neon-${PV}.tar.gz \
|
|
file://pkgconfig.patch \
|
|
file://0001-Disable-installing-documentation.patch \
|
|
file://run-ptest \
|
|
"
|
|
|
|
SRC_URI[sha256sum] = "f98ce3c74300be05eddf05dccbdca498b14d40c289f773195dd1a559cffa5856"
|
|
|
|
inherit autotools-brokensep binconfig-disabled lib_package pkgconfig ptest gettext
|
|
|
|
EXTRA_AUTORECONF += "-I macros"
|
|
|
|
# Enable gnutls or openssl, not both
|
|
PACKAGECONFIG ?= "expat gnutls libproxy webdav zlib"
|
|
PACKAGECONFIG:class-native = "expat gnutls webdav zlib"
|
|
|
|
PACKAGECONFIG[expat] = "--with-expat,--without-expat,expat"
|
|
PACKAGECONFIG[gnutls] = "--with-ssl=gnutls,,gnutls"
|
|
PACKAGECONFIG[gssapi] = "--with-gssapi,--without-gssapi,krb5"
|
|
PACKAGECONFIG[libproxy] = "--with-libproxy,--without-libproxy,libproxy"
|
|
PACKAGECONFIG[libxml2] = "--with-libxml2,--without-libxml2,libxml2"
|
|
PACKAGECONFIG[openssl] = "--with-ssl=openssl,,openssl"
|
|
PACKAGECONFIG[webdav] = "--enable-webdav,--disable-webdav,"
|
|
PACKAGECONFIG[zlib] = "--with-zlib,--without-zlib,zlib"
|
|
|
|
EXTRA_OECONF += "--enable-shared --enable-threadsafe-ssl=posix"
|
|
|
|
do_configure:prepend() {
|
|
echo "${PV}" > ${S}/.version
|
|
}
|
|
|
|
do_compile:append() {
|
|
if ${@bb.utils.contains('USE_NLS', 'yes', 'true', 'false', d)}; then
|
|
oe_runmake compile-gmo
|
|
fi
|
|
oe_runmake -C test
|
|
}
|
|
|
|
do_install_ptest(){
|
|
BASIC_TESTS="auth basic redirect request session socket string-tests \
|
|
stubs uri-tests util-tests"
|
|
DAV_TESTS="acl3744 lock oldacl props xml xmlreq"
|
|
mkdir "${D}${PTEST_PATH}/test"
|
|
for i in ${BASIC_TESTS} ${DAV_TESTS}
|
|
do
|
|
install -m 0755 "${B}/test/${i}" \
|
|
"${D}${PTEST_PATH}/test"
|
|
done
|
|
}
|
|
|
|
BINCONFIG = "${bindir}/neon-config"
|
|
|
|
BBCLASSEXTEND = "native"
|