mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-27 07:57:27 +00:00
Hongxu Jia
4fe6bf337a
$ echo 'MACHINE = "qemux86"' >> conf/local.conf $ bitbake thin-provisioning-tools ``` error[E0080]: index out of bounds: the length is 1 but the index is 4 --> tmp/work/core2-32-wrs-linux/thin-provisioning-tools/1.3.1/build/target/release/build/devicemapper-sys-f88f57f28cd965d2/out/dm-bindings.rs:3:8718 | 3 | ...usize] ; ["Alignment of dm_ioctl"] [:: std :: mem :: align_of :: < dm_ioctl > () - 4usize] ; ["Offset of field: dm_ioctl::version"... | ^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^^ evaluation of `_` failed here ``` Inherit siteinfo to use SITEINFO_BITS replace TUNE_FEATURES to test 32bit BSPs Signed-off-by: Hongxu Jia <hongxu.jia@windriver.com> Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
65 lines
2.0 KiB
BlitzBasic
65 lines
2.0 KiB
BlitzBasic
SUMMARY = "Tools of dm-thin device-mapper"
|
|
DESCRIPTION = "A suite of tools for manipulating the metadata of the dm-thin device-mapper target."
|
|
HOMEPAGE = "https://github.com/device-mapper-utils/thin-provisioning-tools"
|
|
LICENSE = "GPL-3.0-only"
|
|
SECTION = "devel"
|
|
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=1ebbd3e34237af26da5dc08a4e440464"
|
|
|
|
SRC_URI = " \
|
|
git://github.com/device-mapper-utils/thin-provisioning-tools;branch=main;protocol=https;tag=v${PV} \
|
|
file://0001-Use-portable-atomics-crate.patch \
|
|
file://disable-cargo-metadata.patch \
|
|
${@bb.utils.contains('SITEINFO_BITS', '32', \
|
|
'file://dms-no-layout-check.patch;patchdir=${CARGO_VENDORING_DIRECTORY}/devicemapper-sys-0.3.3', \
|
|
'', d)} \
|
|
"
|
|
|
|
SRCREV = "8b663fb4c6fb8e52ca06cea57b986c5ba45f668d"
|
|
UPSTREAM_CHECK_GITTAGREGEX = "v(?P<pver>\d+(\.\d+)+)"
|
|
|
|
inherit cargo cargo-update-recipe-crates
|
|
inherit pkgconfig siteinfo
|
|
|
|
DEPENDS += "udev libdevmapper libdevmapper-native clang-native"
|
|
|
|
export LIBCLANG_PATH = "${STAGING_LIBDIR_NATIVE}"
|
|
# Remove octeontx2 specific CPU flags that may cause issues with bindgen
|
|
BINDGEN_EXTRA_CLANG_ARGS = "${HOST_CC_ARCH}${TOOLCHAIN_OPTIONS} --target=${TARGET_SYS}"
|
|
BINDGEN_EXTRA_CLANG_ARGS:remove = "-mcpu=octeontx2+crypto"
|
|
export BINDGEN_EXTRA_CLANG_ARGS
|
|
|
|
require ${BPN}-crates.inc
|
|
|
|
do_install:append() {
|
|
install -d ${D}${sbindir}
|
|
mv ${D}${bindir}/pdata_tools ${D}${sbindir}/pdata_tools
|
|
rmdir --ignore-fail-on-non-empty ${D}${bindir}
|
|
|
|
for tool in cache_check \
|
|
cache_dump \
|
|
cache_metadata_size \
|
|
cache_repair \
|
|
cache_restore \
|
|
cache_writeback \
|
|
thin_check \
|
|
thin_delta \
|
|
thin_dump \
|
|
thin_ls \
|
|
thin_metadata_size \
|
|
thin_metadata_pack \
|
|
thin_metadata_unpack \
|
|
thin_repair \
|
|
thin_restore \
|
|
thin_rmap \
|
|
thin_shrink \
|
|
thin_trim \
|
|
era_check \
|
|
era_dump \
|
|
era_invalidate \
|
|
era_repair \
|
|
era_restore; do
|
|
ln -sf pdata_tools ${D}${sbindir}/$tool
|
|
done
|
|
}
|