mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-11-13 03:37:15 +00:00
Khem Raj
dfad8e27be
tests/test_docstrings.py imports pytest_examples and tests/test_tzinfo.py imports pydantic, neither of which the ptest package depends on. pytest stops at the collection errors, so no test ran at all: E ModuleNotFoundError: No module named 'pytest_examples' E ModuleNotFoundError: No module named 'pydantic' Add both. test_docstrings.py then looks for core_schema.py and README.md relative to the source tree, so install README.md and point it at the installed core_schema.py. Skip the ruff lint step of the docstring examples, as python3-pydantic does. Outside the source tree ruff doesn't treat pydantic_core as first party and flags the import order (I001) of 23 examples, plus a couple of style rules newer than the examples. The examples are still run. 6025 tests pass and 126 are skipped on qemux86-64. AI-Generated: Uses Claude Code Signed-off-by: Khem Raj <khem.raj@oss.qualcomm.com>
56 lines
2.0 KiB
BlitzBasic
56 lines
2.0 KiB
BlitzBasic
SUMMARY = "Provides the core functionality for pydantic validation and serialization."
|
|
DESCRIPTION = "This package provides the core functionality for \
|
|
pydantic validation and serialization.\
|
|
\
|
|
Pydantic-core is currently around 17x faster than pydantic V1."
|
|
HOMEPAGE = "https://github.com/pydantic/pydantic-core"
|
|
|
|
LICENSE = "MIT"
|
|
LIC_FILES_CHKSUM = "file://LICENSE;md5=ab599c188b4a314d2856b3a55030c75c"
|
|
|
|
require ${BPN}-crates.inc
|
|
|
|
SRC_URI += "file://0001-Upgrade-radium-to-1.0.patch;patchdir=${UNPACKDIR}/cargo_home/bitbake/bitvec-1.0.1/"
|
|
SRC_URI += "file://atomic.patch;patchdir=${UNPACKDIR}/cargo_home/bitbake/radium-1.1.0/"
|
|
SRC_URI += "file://0001-cargo.toml-Update-bitvec-to-use-radium-1.x.patch"
|
|
SRC_URI[sha256sum] = "e50d7b94baac6c7d09927fa5ca5800a0c7ee5015c7fcff65beb3a1931b5a6e09"
|
|
|
|
DEPENDS = "python3-maturin-native python3-typing-extensions"
|
|
|
|
inherit pypi cargo-update-recipe-crates python_maturin ptest-python-pytest
|
|
|
|
RDEPENDS:${PN} += " \
|
|
python3-compression \
|
|
python3-typing-extensions \
|
|
"
|
|
|
|
INSANE_SKIP:${PN} = "already-stripped"
|
|
|
|
# python3-misc is for Lib/timeit.py which is not split out elsewhere
|
|
RDEPENDS:${PN}-ptest += "\
|
|
python3-dateutil \
|
|
python3-dirty-equals \
|
|
python3-hypothesis \
|
|
python3-inline-snapshot \
|
|
python3-misc \
|
|
python3-pydantic \
|
|
python3-pytest-mock \
|
|
python3-pytest-timeout \
|
|
python3-pytest-benchmark \
|
|
python3-pytest-examples \
|
|
python3-typing-inspection \
|
|
python3-tzdata \
|
|
python3-zoneinfo \
|
|
"
|
|
|
|
do_install_ptest:append () {
|
|
cp -rf ${S}/tests/ ${D}${PTEST_PATH}/
|
|
install -m 0644 ${S}/README.md ${D}${PTEST_PATH}/
|
|
sed -i -e "s|PYDANTIC_CORE_DIR / 'python/pydantic_core/core_schema.py'|'${PYTHON_SITEPACKAGES_DIR}/pydantic_core/core_schema.py'|" \
|
|
-e "s/^ lint_skip = .*/ lint_skip = True/" \
|
|
${D}${PTEST_PATH}/tests/test_docstrings.py
|
|
sed -i -e "/--automake/ s/$/ -k 'not test_model_class_root_validator_wrap and not test_model_class_root_validator_before and not test_model_class_root_validator_after'/" ${D}${PTEST_PATH}/run-ptest
|
|
}
|
|
|
|
BBCLASSEXTEND = "native nativesdk"
|