mirror of
https://github.com/openembedded/meta-openembedded.git
synced 2026-07-16 16:27:27 +00:00
Wang Mingyu
fc221b3211
Changelog:
==========
dco: don't use NetLink to exchange control packets
dco: print version to log if available
dco-linux: remove M_ERRNO flag when printing netlink error message
multi: don't call DCO APIs if DCO is disabled
dco-freebsd: use m->instances[] instead of m->hash
dco-linux: implement dco_get_peer_stats{, multi} API
Set netlink socket to be non-blocking
Ensure n = 2 is set in key2 struct in tls_crypt_v2_unwrap_client_key
Fix memory leaks in open_tun_dco()
Fix memory leaks in HMAC initial packet generation
Use key_state instead of multi for tls_send_payload parameter
Make sending plain text control message session aware
Only update frame calculation if we have a valid link sockets
Improve description of compat-mode
Simplify --compress parsing in options.c
Refuse connection if server pushes an option contradicting allow-compress
Add 'allow-compression stub-only' internally for DCO
Parse compression options and bail out when compression is disabled
tests/unit_tests: Fix 'make distcheck' with subdir-objects enabled
preparing release 2.6.2
dns option: allow up to eight addresses per server
dco: print FreeBSD version
Support --inactive option for DCO
Fix '--inactive <time> 0' behavior for DCO
Print DCO client stats on SIGUSR2
Don't overwrite socket flags when using DCO on Windows
using OpenSSL3 API for EVP PKEY type name reporting
Bugfix: Convert ECDSA signature form pkcs11-helper to DER encoded form
Import some sample certificates into Windows store for testing
Add tests for finding certificates in Windows cert store
Refactor SSL_CTX_use_CryptoAPI_certificate()
Add a test for signing with certificates in Windows store
Unit tests: add test for SSL_CTX_use_Cryptoapi_certificate()
Improve error message on short read from socks proxy
Make error in setting metric for IPv6 interface non-fatal
Signed-off-by: Wang Mingyu <wangmy@fujitsu.com>
Signed-off-by: Khem Raj <raj.khem@gmail.com>
78 lines
3.2 KiB
BlitzBasic
78 lines
3.2 KiB
BlitzBasic
SUMMARY = "A full-featured SSL VPN solution via tun device."
|
|
HOMEPAGE = "https://openvpn.net/"
|
|
SECTION = "net"
|
|
LICENSE = "GPL-2.0-only"
|
|
LIC_FILES_CHKSUM = "file://COPYING;md5=3170e982baae61dbb8de963317d1ac94"
|
|
DEPENDS = "lzo lz4 openssl iproute2 libcap-ng ${@bb.utils.contains('DISTRO_FEATURES', 'pam', 'libpam', '', d)}"
|
|
|
|
inherit autotools systemd update-rc.d pkgconfig
|
|
|
|
SRC_URI = "http://swupdate.openvpn.org/community/releases/${BP}.tar.gz \
|
|
file://0001-configure.ac-eliminate-build-path-from-openvpn-versi.patch \
|
|
file://openvpn \
|
|
"
|
|
|
|
UPSTREAM_CHECK_URI = "https://openvpn.net/community-downloads"
|
|
|
|
SRC_URI[sha256sum] = "42d561a9af150b21bc914e3b7aa09f88013d2ffa6d5ce75a025a3b34caa948d4"
|
|
|
|
# CVE-2020-7224 and CVE-2020-27569 are for Aviatrix OpenVPN client, not for openvpn.
|
|
CVE_CHECK_IGNORE += "CVE-2020-7224 CVE-2020-27569"
|
|
|
|
INITSCRIPT_PACKAGES = "${PN}"
|
|
INITSCRIPT_NAME:${PN} = "openvpn"
|
|
INITSCRIPT_PARAMS:${PN} = "start 10 2 3 4 5 . stop 70 0 1 6 ."
|
|
|
|
CFLAGS += "-fno-inline"
|
|
|
|
# I want openvpn to be able to read password from file (hrw)
|
|
EXTRA_OECONF += "--enable-iproute2"
|
|
EXTRA_OECONF += "${@bb.utils.contains('DISTRO_FEATURES', 'pam', '', '--disable-plugin-auth-pam', d)}"
|
|
|
|
# Explicitly specify IPROUTE to bypass the configure-time check for /sbin/ip on the host.
|
|
EXTRA_OECONF += "IPROUTE=${base_sbindir}/ip"
|
|
|
|
EXTRA_OECONF += "SYSTEMD_UNIT_DIR=${systemd_system_unitdir} \
|
|
TMPFILES_DIR=${nonarch_libdir}/tmpfiles.d \
|
|
"
|
|
|
|
PACKAGECONFIG ??= "${@bb.utils.filter('DISTRO_FEATURES', 'systemd', d)} \
|
|
${@bb.utils.filter('DISTRO_FEATURES', 'selinux', d)} \
|
|
"
|
|
|
|
PACKAGECONFIG[systemd] = "--enable-systemd,--disable-systemd,systemd"
|
|
PACKAGECONFIG[selinux] = "--enable-selinux,--disable-selinux,libselinux"
|
|
|
|
do_install:append() {
|
|
install -d ${D}/${sysconfdir}/init.d
|
|
install -m 755 ${WORKDIR}/openvpn ${D}/${sysconfdir}/init.d
|
|
|
|
install -d ${D}/${sysconfdir}/openvpn
|
|
install -d ${D}/${sysconfdir}/openvpn/server
|
|
install -d ${D}/${sysconfdir}/openvpn/client
|
|
|
|
install -d ${D}/${sysconfdir}/openvpn/sample
|
|
install -m 644 ${S}/sample/sample-config-files/loopback-server ${D}${sysconfdir}/openvpn/sample/loopback-server.conf
|
|
install -m 644 ${S}/sample/sample-config-files/loopback-client ${D}${sysconfdir}/openvpn/sample/loopback-client.conf
|
|
install -dm 755 ${D}${sysconfdir}/openvpn/sample/sample-config-files
|
|
install -dm 755 ${D}${sysconfdir}/openvpn/sample/sample-keys
|
|
install -dm 755 ${D}${sysconfdir}/openvpn/sample/sample-scripts
|
|
install -m 644 ${S}/sample/sample-config-files/* ${D}${sysconfdir}/openvpn/sample/sample-config-files
|
|
install -m 644 ${S}/sample/sample-keys/* ${D}${sysconfdir}/openvpn/sample/sample-keys
|
|
install -m 644 ${S}/sample/sample-scripts/* ${D}${sysconfdir}/openvpn/sample/sample-scripts
|
|
|
|
install -d -m 710 ${D}/${localstatedir}/lib/openvpn
|
|
}
|
|
|
|
PACKAGES =+ " ${PN}-sample "
|
|
|
|
RRECOMMENDS:${PN} = "kernel-module-tun"
|
|
|
|
FILES:${PN}-dbg += "${libdir}/openvpn/plugins/.debug"
|
|
FILES:${PN} += "${systemd_system_unitdir}/openvpn-server@.service \
|
|
${systemd_system_unitdir}/openvpn-client@.service \
|
|
${nonarch_libdir}/tmpfiles.d \
|
|
"
|
|
FILES:${PN}-sample = "${sysconfdir}/openvpn/sample/ \
|
|
"
|